ricc

リカッチ方程式

呼び出し手順

[X,RCOND,FERR]=ricc(A,B,C,"cont""method")
[X,RCOND,FERR]=ricc(F,G,H,"disc","method")

パラメータ

A,B,C: 適当な次元の実数行列
F,G,H: 適当な次元の実数行列
X: 実数行列
"cont","disc"': 規定の文字列 (連続または離散を表すフラグ)
method: 連続時間システムの場合は'schr' または 'sign', 離散時間システムの場合は'schr' または'invf'

説明

リカッチソルバ.

連続時間:

X=ricc(A,B,C,'cont')

により連続時間 ARE の解が得られる

A'*X+X*A-X*B*X+C=0 .

B およびC は非負定とする. (A,G) は Bのフルランク分解G*G'により可安定とする.

(A,H) はCのフルランク分解H*H'により可検出とする.

離散時間:

X=ricc(F,G,H,'disc')

により離散時間AREの解が得られる

X=F'*X*F-F'*X*G1*((G2+G1'*X*G1)^-1)*G1'*X*F+H

F は可逆であり、 G = G1*inv(G2)*G1'とする.

(F,G1)は可安定, (C,F) は Hのフルランク分解 C'*Cを用いて可検出であることとする. より適する場合, ric_desc を使用すること.

C, D は対象行列である. 行列 A, C および Dに対応する行列ペンシルが,絶対値が 1より小さい N個の固有値を有するものとする.

解のエラー境界と推定条件も出力される. 行列 A, C および D において, 対応するハミルトン行列が実部が負となるN個の固有値を有するものとする.

例

//Standard formulas to compute Riccati solutions
A=rand(3,3);B=rand(3,2);C=rand(3,3);C=C*C';R=rand(2,2);R=R*R'+eye();
B=B*inv(R)*B';
X=ricc(A,B,C,'cont');
norm(A'*X+X*A-X*B*X+C,1)
H=[A -B;-C -A'];
[T,d]=schur(eye(H),H,'cont');T=T(:,1:d);
X1=T(4:6,:)/T(1:3,:);
norm(X1-X,1)
[T,d]=schur(H,'cont');T=T(:,1:d);
X2=T(4:6,:)/T(1:3,:);
norm(X2-X,1)
//       Discrete time case
F=A;B=rand(3,2);G1=B;G2=R;G=G1/G2*G1';H=C;
X=ricc(F,G,H,'disc');
norm(F'*X*F-(F'*X*G1/(G2+G1'*X*G1))*(G1'*X*F)+H-X)
H1=[eye(3,3) G;zeros(3,3) F'];
H2=[F zeros(3,3);-H eye(3,3)];
[T,d]=schur(H2,H1,'disc');T=T(:,1:d);X1=T(4:6,:)/T(1:3,:);
norm(X1-X,1)
Fi=inv(F);
Hami=[Fi Fi*G;H*Fi F'+H*Fi*G];
[T,d]=schur(Hami,'d');T=T(:,1:d);
Fit=inv(F');
Ham=[F+G*Fit*H -G*Fit;-Fit*H Fit];
[T,d]=schur(Ham,'d');T=T(:,1:d);X2=T(4:6,:)/T(1:3,:);
norm(X2-X,1)

参照

作者

P. Petkov

使用する関数

参照: SCI/modules/cacsd/src/slicot/riccpack.f

<< ric_desc

CACSD

riccati >>

Copyright (c) 2022-2024 (Dassault Systèmes)
Copyright (c) 2017-2022 (ESI Group)
Copyright (c) 2011-2017 (Scilab Enterprises)
Copyright (c) 1989-2012 (INRIA)
Copyright (c) 1989-2007 (ENPC)
with contributors

Last updated:
Wed Jan 26 16:25:08 CET 2011