Scilab Website | Contribute with GitLab | Mailing list archives | ATOMS toolboxes
Scilab Online Help
5.3.1 - 日本語

Change language to:
English - Français - Português

Please note that the recommended version of Scilab is 2024.0.0. This page might be outdated.
See the recommended documentation of this function

Scilab help >> Signal Processing > phc

phc

Markovian表現

呼び出し手順

[H,F,G]=phc(hk,d,r)

パラメータs

hk

ハンケル行列

d

観測量の次元

r

指定する近似モデルの状態量の次元

H, F, G

Markovianモデルの行列

説明

確率過程の共分散系列から構築されたハンケル行列から 主ハンケル要素近似法により Markovian表現の行列H, F, Gを計算する関数.

//This example may usefully be compared with the results from 
//the 'levin' macro (see the corresponding help and example)
//
//We consider the process defined by two sinusoids (1Hz and 2 Hz) 
//in additive Gaussian noise (this is the observation); 
//the simulated process is sampled at 10 Hz.

t=0:.1:100;rand('normal');
y=sin(2*%pi*t)+sin(2*%pi*2*t);y=y+rand(y);plot(t,y)

//covariance of y

nlag=128;
c=corr(y,nlag);

//hankel matrix from the covariance sequence
//(we can choose to take more information from covariance
//by taking greater n and m; try it to compare the results !

n=20;m=20;
h=hank(n,m,c);

//compute the Markov representation (mh,mf,mg)
//We just take here a state dimension equal to 4 :
//this is the rather difficult problem of estimating the order !
//Try varying ns ! 
//(the observation dimension is here equal to one)

ns=4;
[mh,mf,mg]=phc(h,1,ns);

//verify that the spectrum of mf contains the 
//frequency spectrum of the observed process y
//(remember that y is sampled -in our example 
//at 10Hz (T=0.1s) so that we need 
//to retrieve the original frequencies through the log 
//and correct scaling by the frequency sampling)

s=spec(mf);s=log(s);
s=s/2/%pi/.1;

//now we get the estimated spectrum
imag(s),

参照

  • levin — (多次元)LevinsonアルゴリズムによりToeplitz システムを解く
<< %sn Signal Processing pspect >>

Copyright (c) 2022-2023 (Dassault Systèmes)
Copyright (c) 2017-2022 (ESI Group)
Copyright (c) 2011-2017 (Scilab Enterprises)
Copyright (c) 1989-2012 (INRIA)
Copyright (c) 1989-2007 (ENPC)
with contributors
Last updated:
Thu Mar 03 11:00:56 CET 2011