Scilab Website | Contribute with GitLab | Mailing list archives | ATOMS toolboxes
Scilab Online Help
5.5.1 - 日本語

Change language to:
English - Français - Português - Русский

Please note that the recommended version of Scilab is 2024.0.0. This page might be outdated.
See the recommended documentation of this function

Scilabヘルプ >> GUI > uicontrol

uicontrol

グラフィックユーザーインターフェイスオブジェクトを作成

呼び出し手順

h = uicontrol(PropertyName,PropertyValue,...)
h = uicontrol(parent,PropertyName,PropertyValue,...)
h = uicontrol(uich)

説明

このルーチンは図にオブジェクトを作成します.

図のオブジェクトが(最初のパラメータとして)指定された場合, この図にuicontrolが作成されます.ハンドルが指定されない場合, uicontrolが(gcf()のコールにより得られる) カレントの図に作成されます. カレントの図が存在しない場合, uicontrolを作成する前に作成されます.

コントロールが作成される際に,パラメータとして指定されたプロパティが 適当な値で設定されます. これはuicontrolを作成する際と同じで,この後,プロパティが set()コマンドで設定されます. それにもかからわらず, 一般に uicontrol()のコールにより プロパティを設定する方がより効率的です. Scilabと全てのグラフィックオブジェクトは 適当な機構により通信を行います. つまり,適当なuicontrolを作成するには, 適当なフィールドの使用方法を知る必要があります.

h= uicontrol(PropertyName, PropertyValue,...) は, uicontrolを作成し,指定したプロパティを割付,値を代入します. 値が指定されないプロパティにはデフォルト値が代入されます. デフォルトの uicontrol の形式は "Pushbutton" です. デフォルトの親は,カレントの図です. これらおよび他のプロパティに関する情報についてはプロパティの節を 参照ください.

h= uicontrol(parent, PropertyName, PropertyValue,...) はハンドルparentで指定されたオブジェクトにuicontrolを作成します. 親プロパティと異なる値を指定する場合, 親プロパティの値が優先されます. parentは図のハンドルです.

h= uicontrol(uich) はuichにより指定された uicontrolにフォーカスを与えます.

利用可能な全プロパティとその説明を uicontrolプロパティ ヘルプページで参照可能です.

uicontrolsレンダリングとプロパティ表示は コンソールプロパティ によりカスタマイズできます.

利用可能なスタイル

利用可能なスタイルを以下に示します. uicontrolstyleは 作成時に"Style"プロパティにより設定する 必要があり, uicontrol の作成後は変更できません.

  • Checkbox: 2種類の状態を有するボタン (複数の独立した選択で使用されます).

  • Edit: 編集可能なテキスト領域.

  • Frame: 他のuicontrolのコンテナ.

  • Image: 指定した画像が表示されるコンポーネント.

  • Layer: frameスタイルのuicontrol用コンテナで, value プロパティを用いてプログラムにより 切替できます.

  • Listbox: スクロール可能なリスト要素を表すコントロール. 要素はマウスで選択できます.

  • Popupmenu: クリックした際にメニューが現れるボタン

  • Pushbutton: (デフォルトのスタイル) 矩形のボタンで,通常コールバックを実行する際に使用されます.

  • Radiobutton: 2つの状態を有するボタン. RadioButtons は相互に排他であることを意図しています.

    グループを使用しない場合, コードに相互に排他である動作を実装する必要があります (uicontrolプロパティGroupNameプロパティを参照).

  • Slider: 縮尺制御, マウスで範囲内の値を設定する際に使用されます.

  • Spinner: ユーザが固定刻みで範囲内の値を選択/編集することを可能とするコンポーネント.

  • Tab: frame スタイルの uicontrols のコンテナで, 指定したタイトルやアイコンをクリックすることにより切替できるようにします.

    フレームに指定されたフォント関連プロパティは タブレベルにも使用されます.

  • Table: 編集可能な表.

  • Text: テキストコントロールl (通常 static).

Examples

f=figure();
// 図を作成
h=uicontrol(f,'style','listbox', ...
 'position', [10 10 150 160]);
// リストボックスを作成
set(h, 'string', "item 1|item 2|item3");
// リストを埋める
set(h, 'value', [1 3]);
// リストで要素1と3を選択
close(f);
// close the figure

uicontrol関数はオーバーロードできます

// mlistを作成
mymlist = mlist(['objid','A','B'],[],[]);
// objidのset / getをオーバーロード
function result=%objid_uicontrol(varargin)
  // res = uicontrol(mymlist,'A');
  obj_tmp   = varargin(1);
  field_tmp = varargin(2);
  mprintf('uicontrol on an object of type %s, field = %s\n', typeof(obj_tmp), field_tmp);
  result = %t;
endfunction
res = uicontrol(mymlist,'property');

Pushbuttons or Text can have LaTeX or MathML label

// LaTeX
f=figure();
h=uicontrol(f,"style","pushbutton","string","$x^2$");
// MathML
hh=uicontrol(f,"style","pushbutton","string","<msup><mi>x</mi><mn>2</mn></msup>");
hh.Position = h.Position + [50, 0, 0, 0];
// Text
h=uicontrol(f,"Style","text","string","$\Gamma(s)=\int_0^\infty t^{s-1}\mathrm{e}^{-t}\,\mathrm{d}t$");
// 小さすぎる場合
h.fontsize=20
// 編集可能な表を図に含める:
// データの表を構築:
params = [" " "Country" "Population [Mh]" "Temp.[A°C]" ];
towns = ["Mexico" "Paris" "Tokyo" "Singapour"]';
country = ["Mexico" "France" "Japan" "Singapour"]';
pop  = string([22.41 11.77 33.41 4.24]');
temp = string([26 19 22 17]');
table = [params; [ towns country pop temp ]]
f = gcf();
clf
as = f.axes_size;  // [width height]
ut = uicontrol("style","table",..
               "string",table,..
               "position",[5 as(2)-100 300 87],.. // => @top left corner of figure
               "tooltipstring","Data from majors towns")
// 表の中の値のいくつかを手修正. これらをUIから取得:
matrix(ut.string,size(table))

参照

  • uicontrol_properties — uicontrolプロパティの説明.
  • figure — 図を作成する
  • set — グラフィックエンティティオブジェクトまたは またはユーザインターフェイスオブジェクトのプロパティの値を設定する.
  • get — グラフィックエンティティまたはユーザーインターフェイスオブジェクト からプロパティの値を取得する.
  • uimenu — 図にメニューまたはサブメニューを作成する
  • LaTeXおよびMathML — LaTeX またはMathML言語によりScilabグラフィックスで数式を表示する.

履歴

バージョン記述
5.5.0

新スタイルが追加されました:

  • Tab
  • Spinner
  • Layer

uicontrolsレンダリングはオペレーティングシステムの ルックアンドフィールに基づくようになりました (コンソールプロパティ 参照).

uicontrolsハンドルの表示はJavaレンダリングにより使用される プロパティに制限されるようになりました (コンソールプロパティ 参照).

Report an issue
<< uicontextmenu GUI uicontrolプロパティ >>

Copyright (c) 2022-2023 (Dassault Systèmes)
Copyright (c) 2017-2022 (ESI Group)
Copyright (c) 2011-2017 (Scilab Enterprises)
Copyright (c) 1989-2012 (INRIA)
Copyright (c) 1989-2007 (ENPC)
with contributors
Last updated:
Thu Oct 02 13:58:25 CEST 2014