poly

Arguments

vname

Mot : nom de la variable du polynôme. Les caractères autorisés sont les mêmes que ceux utilisables pour les noms de variables (voir les règles de nommage).

vec

scalaire, vecteur, ou matrice non carrée de nombres décimaux ou complexes.

"roots" ou "r" (par défaut), ou "coeff" ou "c"

Indicateur précisant la nature des éléments de vec: racines ou coefficients du polynôme à construire.

p

polynôme unique ayant les racines ou les coefficients donnés.

matNN

Matrice carrée de nombres décimaux ou complexes.

Pc

Polynôme caractéristique de la matrice donnée, = det(x*eye() - matNN), avec la variable symbolique x = poly(0,vname).

Description

Lorsqu'un vecteur ou une matrice non carrée vec est fourni,

• poly(vec, "x") ou poly(vec, "x", "roots") construit le polynôme dont les racines sont les éléments de vec, et "x" est le nom de la variable indéterminée.

  degree(p)==length(vec) poly() et roots() sont réciproques. Toute racine infinie produit un coefficient de haut degré nul. Dans ce cas, le degré effectif de p est inférieur à length(vec). Par exemple, poly([-%inf -1 2 %inf ], "x") produit (x-2)(x+1) de degré 2.

  L'expression x = poly(0,"x") définit le monôme p(x)=x, lequel peut ensuite être utilisé avec les opérateurs usuels +, -, *, / et les fonctions communes telles que sum().

  3 monômes sont disponibles dans les variables prédéfinies %s, %z, et $. Ce dernier est principalement connu et utilisé pour représenter le nombre d'éléments d'une ligne / colonne... dans un tableau.

• poly(vec, "x", "coeff") construit le polynôme de variable "x" dont les coefficients de degrés croissants sont les éléments de vec (vec(1) est le terme constant du polynôme). Les coefficients de plus hauts degrés nuls (en fin de vec) sont ignorés.

  Réciproquement, coeff(p) fournit les coefficients de polynômes donnés.

Une matrice carrée matNN est fournie,

pm = poly(matNN,vname) contruit et fournit le polynôme caractéristique de matNN, de variable indéterminée nommée par vname : p = det(x*eye() - matNN), avec x = poly(0,vname).

Exemples

Polynôme défini par des coefficients choisis :

// Construction directe :
x = poly(0,"x");
p = 1 - x + 2*x^3

// Avec poly():
p2 = poly([1 -1 0 2], "x", "coeff")

// Avec des coefficients nuls aux plus hauts degrés :
p3 = poly([2 0 -3 zeros(1,8)], "y", "coeff")

--> p = 1 - x + 2*x^3
 p  =
           3
   1 -x +2x

--> p2 = poly([1 -1 0 2], "x", "coeff")
 p2  =
           3
   1 -x +2x

--> p3 = poly([2 0 -3 zeros(1,8)], "y", "coeff")
 p3  =
        2
   2 -3y

Polynôme à racines choisies :

// Construction directe :
x = poly(0,"x");
p = (1-x)^2 * (2+x)

// Avec poly():
p2 = poly([1 1 -2], "x")

// Avec des racines infinies :
p3 = poly([%inf -1 2 %inf -%inf], "x")

--> p = (1-x)^2 * (2+x)
 p  =
           3
   2 -3x +x

--> p2 = poly([1 1 -2], "x")
 p2  =
           3
   2 -3x +x

--> p3 = poly([%inf -1 2 %inf -%inf], "x")
 p3  =
          2
  -2 -x +x

Polynôme caractéristique d'une matrice carrée :

A = [1 2 ; 3 -4]
poly(A, "x")

--> A = [1 2 ; 3 -4]
 A  =
   1.   2.
   3.  -4.

--> poly(A, "x")
 ans  =
            2
  -10 +3x +x

Voir aussi

• inv_coeff — construction d'une matrice polynomiale à partir des coefficients
• coeff — coefficients d'une matrice de polynômes
• roots — racines d'un polynôme
• varn — variable symbolique d'un polynôme ou d'une fraction rationnelle
• horner — évaluation d'un polynôme ou d'une fraction rationnelle
• %s — A variable used to define polynomials.
• %z — A variable used to define polynomials.
• rational — Fraction rationnelle
• rlist — définition d'une fraction rationnelle

Historique