contourf

Parâmetrtos

x,y

dois vetores de reais de tamanhos n1 e n2 definindo o grid.

z

matriz de reais de tamanho (n1,n2), os valores da função.

nz

os valores de nível ou o número de níveis.

-

Se nz for um inteiro, seu valor fornece o número de níveis igualmente espaçados de zmin a zmax como segue:

z= zmin + (1:nz)*(zmax-zmin)/(nz+1)

Note que os níveis zmin e zmax não são desenhados (genericamente eles são reduzidos a pontos) mas podem ser adicionados através de

[im,jm] = find(z == zmin);     // ou zmax 
plot2d(x(im)',y(jm)',-9,"000")

-

Se nz for um vetor, nz(i) fornece o valor da i-ésima curva de nível.

style,strf,leg,rect,nax

ver plot2d. O argumento style fornece as cores a serem utilizadas pelas curvas de nível. Deve ter o mesmo tamanho que o número de níveis.

Descrição

contourf pinta a superfície entre duas curvas de nível consecutivas z=f(x,y) em um esboço 2d. Os valores de f(x,y) são fornecidos pela matriz z nos pontos de grid definidos por x e y.

Você pode mudar o formato dos pontos flutuantes impressos sobre os níveis utilizando xset("fpf",string) onde string fornece o formato em sintaxe de formato C ( por exemplo string="%.3f"). Use string="" para voltar ao formato padrão.

Entre com o comando contourf() para visualizar uma demonstração.

Exemplos

contourf(1:10,1:10,rand(10,10),5,1:5,"011"," ",[0,0,11,11])

function z=peaks(x, y)
x1=x(:).*.ones(1,size(y,'*'));
y1=y(:)'.*.ones(size(x,'*'),1);
z =  (3*(1-x1).^2).*exp(-(x1.^2) - (y1+1).^2) ... 
   - 10*(x1/5 - x1.^3 - y1.^5).*exp(-x1.^2-y1.^2) ... 
   - 1/3*exp(-(x1+1).^2 - y1.^2) 
endfunction

function z=peakit()
x=-4:0.1:4;y=x;z=peaks(x,y);
endfunction

z=peakit();

levels=[-6:-1,-logspace(-5,0,10),logspace(-5,0,10),1:8];
m=size(levels,'*');
n = fix(3/8*m);
r = [(1:n)'/n; ones(m-n,1)];
g = [zeros(n,1); (1:n)'/n; ones(m-2*n,1)];
b = [zeros(2*n,1); (1:m-2*n)'/(m-2*n)];
h = [r g b];
xset('colormap',h);
xset('fpf',' ');
clf();
contourf([],[],z,[-6:-1,-logspace(-5,0,10),logspace(-5,0,10),1:8],0*ones(1,m))

xset('fpf','');
clf();
contourf([],[],z,[-6:-1,-logspace(-5,0,10),logspace(-5,0,10),1:8]);

Ver Também

• contour
• fcontour
• fcontour2d
• contour2di
• plot2d
• xset

Autor

J.Ph.C.