replot

Paramètres

area

vecteur [xmin ymin xmax ymax] ou [xmin ymin zmin xmax ymax zmax]: nouvelles bornes de la zone à réafficher. Utiliser %nan pour conserver une borne telle quelle.

axesHandles

Vecteur d'identifiants graphiques de type Axes: repères graphiques à retailler. Par défaut, le repère graphique actif de la fenêtre graphique active est considéré.

Description

replot est utilisée pour recadrer les repères graphiques spécifiés par axesHandles (ou par défaut le repère graphique actif de la fenêtre graphique active) en changeant leurs bornes communes spécifiées sous la forme rect = [xmin,ymin, xmax,ymax] ou rect = [xmin,ymin,zmin, xmax,ymax,zmax].

replot modifie les valeurs data_bounds des repères.

La propriété tight_limits des repères doit être mise à  "on" pour sélectionner strictement ces bornes (voir axes_properties).

Exemples

// Premier exemple
x=[0:0.1:2*%pi]';
plot2d(x,sin(x))
replot([-1,-1,10,2])

// second exemple
xdel(winsid());
plot() // plot demo
f=gcf();
replot([-1,-1,10,2],f.children(1)) // specify axes handle's value
replot([-3,-2,8,4],f.children(2))

// Les bornes signalées par la valeur %nan ne sont pas modifiées :
x = linspace(0,360,200).';
clf
plot2d(x,[sind(x) tand(x)])
ax = gca();
ax.data_bounds                // bornes initiales
replot([%nan,-10,%nan,10])    // Seules Ymin and Ymax sont modifiées
ax.data_bounds                // nouvelles bornes
// En 3D, les bornes en Z peuvent également être modifiées :
clf
x = linspace(-4,4,100);
X = meshgrid(x);
R = (X-0.5).^2 + (X.'+0.7).^2;
Z = sinc(R);
surf(x-0.5,x+0.7,Z)
f = gcf();
f.color_map = autumncolormap(100);
ax = gca();
ax.data_bounds
sleep(3000)
replot([-5 0 -0.4 0 5 0.5])
ax.data_bounds
// Plusieurs repères graphiques peuvent être simultanément recadrés :
clf
x = linspace(-%pi,%pi,400);
subplot(2,2,1)
plot2d(x,sin(1 ./sqrt(abs(x))))
ax1 = gca();
subplot(2,2,2)
plot2d(x,sinh(sqrt(abs(x))))
subplot(2,1,2)
plot2d(x,cos(1 ./sqrt(abs(x))))
ax2 = gca();
sleep(4000)
f = gcf();
replot([-1 %nan 1.5 %nan], [ax1 ax2])

Voir aussi

• zoom_rect — zoom a selection of the current graphic figure
• rubberbox — rubberband box for rectangle selection
• axes_properties — description of the axes entity properties

Historique