Scilab Website | Contribute with GitLab | Mailing list archives | ATOMS toolboxes
Scilab Online Help
5.3.3 - 日本語

Change language to:
English - Français - Português

Please note that the recommended version of Scilab is 2024.0.0. This page might be outdated.
See the recommended documentation of this function

Scilab help >> Graphics > xsetech

xsetech

プロット時にグラフィックウインドのサブウインドウを設定

呼び出し手順

xsetech(wrect,[frect,logflag])
xsetech(wrect=[...],frect=[..],logflag="..", arect=[...])
xsetech()

パラメータ

wrect

大きさ 4のベクトル, 使用するサブウインドウを定義します.

frect

大きさ 4のベクトル.

logflag

大きさ 2の文字列 "xy", ただし x および y は "n" または "l"とします. "n" は通常のスケール, "l"は対数スケールを意味します. xはx軸,yはy軸を意味します.

arect

大きさ4のベクトル.

説明

xsetech は主にプロットに使用されるグラフィックウインドウ のサブウインドウを設定する際に使用されます. サブウインドウはパラメータwrect=[x,y,w,h] (左上の点,幅,高さ)で指定されます. wrectの値は,カレントのグラフィックウインドウの幅または高さの比で指定されます. 例えば,wrect=[0,0,1,1] はグラフィックウインドウ全体を使用することを 意味し, wrect=[0.5,0,0.5,1] はグラフィック領域がグラフィックウインドウの右反面 となることを意味します.

xsetech はカレントの2次元プロットのグラフィックスケールも 設定し,カレントのグラフィックスケールを指定するグラフィックルーチン (例えばplot2dstrf="x0z"または frameflag=0)と組み合わせて使用できます.

frect=[xmin,ymin,xmax,ymax] はグラフィックスケールを 設定する際に使用され, plot2drect引数によく似ています. frect が指定されない場合, グラフィックスケールのカレントの値は変更されません. rectのデフォルト値は [0,0,1,1] (ウインドウ作成時,xset('default')によりデフォルト値に 戻された時,または記録されたグラフィックイベントをclf()で クリアした時)です.

arect=[x_left, x_right,y_up,y_down] はサブウインドウの 中にグラフィックフレームを設定する際に使用されます. グラフィックフレームは(wrectと同様に)カレントのグラフィックサブウインドウの 幅または高さに比例して指定されます. デフォルト値は 1/8*[1,1,1,1]です. arect が指定されない場合, カレントの値は変更されません.

// xsetechパラメータのグラフィカルな説明を得るには以下を入力してください:
exec('SCI/modules/graphics/demos/xsetechfig.sce');

// ここではグラフィックウインドウを2分割するためにxsetechが使用されます
// まず最初のサブウインドウを設定するためにxsetechを使用します 
// and the graphics scale 
xsetech([0,0,1.0,0.5],[-5,-3,5,3])
// グラフィックスケールを使用するためにplot2d に "001"オプションを指定してコールします
// set by xsetech 
plot2d([1:10]',[1:10]',1,"001"," ")
//次に2番目のサブウインドウを設定するためにxsetechを使用します
xsetech([0,0.5,1.0,0.5])
// グラフィックスケールはデフォルトで xsetechにより[0,0,1,1]に設定され,
// plot2d のrect引数により変更します
plot2d([1:10]',[1:10]',1,"011"," ",[-6,-6,6,6])
// 4つのプロットを一つのグラフィックウインドウにプロットします 
clf()
xset("font",2,0)
xsetech([0,0,0.5,0.5]); plot3d()
xsetech([0.5,0,0.5,0.5]); plot2d()
xsetech([0.5,0.5,0.5,0.5]); grayplot()
xsetech([0,0.5,0.5,0.5]); histplot()
// サブウインドウのデフォルト値に戻します
xsetech([0,0,1,1])
// 変更したarectにプロット
clf()
xset("default")
xsetech(arect=[0,0,0,0]) 
x=1:0.1:10;plot2d(x',sin(x)')
clf()
xsetech(arect=[1/8,1/8,1/16,1/4])
x=1:0.1:10;plot2d(x',sin(x)')
clf()
xset("default")

参照

  • xgetech — カレントのグラフィックスケールを取得
  • subplot — グラフィックウインドウをサブウインドウの行列に分割する
  • isoview — 等軸プロットにスケールを設定 (ウインドウの大きさを変更しない)
  • square — 等軸プロットのスケールを設定 (ウインドウの大きさを変更)

作者

J.Ph.C.

<< xset Graphics xsetm >>

Copyright (c) 2022-2023 (Dassault Systèmes)
Copyright (c) 2017-2022 (ESI Group)
Copyright (c) 2011-2017 (Scilab Enterprises)
Copyright (c) 1989-2012 (INRIA)
Copyright (c) 1989-2007 (ENPC)
with contributors
Last updated:
Wed Oct 05 12:12:59 CEST 2011