sylm

Paramètres

a,b

deux polynômes à coefficients réels ou complexes.

S

Matrice carrée de nombres réels ou complexes, de taille degree(a*b).

Description

sylm(a,b) renvoie la matrice de Sylvester associée aux polynômes a et b, i.e. la matrice S telle que :

coeff( a*x + b*y )' = S * [coeff(x)';coeff(y)'].

Si a et b sont premiers entre eux alors

rank(sylm(a,b))=degree(a)+degree(b)) et les instructions

u = sylm(a,b) \ eye(na+nb,1)
x = poly(u(1:nb),'z','coeff')
y = poly(u(nb+1:na+nb),'z','coeff')

calculent les facteurs de Bezout x ainsi que y de degré minimum tels que a*x+b*y = 1

Exemples

x = poly(0,"x");
y = poly([1, 2, 3], "x","coeff")
sylm(x, y)

--> x = poly(0, "x");
--> y = poly([1, 2, 3], "x","coeff")
 y  =
  1 +2x +3x²

--> sylm(x, y)
 ans  =
   0.   0.   1.
   1.   0.   2.
   0.   1.   3.

Résultant de deux polynômes: il peut être défini comme le déterminant de la matrice de Sylvester de ceux-ci. Il est nul si et seulement si les deux polynômes ont au moins une racine en commun.

a = poly([1 2 3 4], "x", "roots")
b = poly([-2 -1 5], "x", "roots")
det(sylm(a, b))

// Cas plus simple
det(sylm((%s+1)^5, (%s+3)^3))
(-3 -(-1))^(5*3)     // valeur attendue

--> a = poly([1 2 3 4],"x","roots")
 a  =
  24 -50x +35x² -10x³ +x⁴

--> b = poly([-2 -1 5],"x","roots")
 b  =
  -10 -13x -2x² +x³

--> det(sylm(a,b))
 ans  =
   1036800.0

--> // Cas plus simple
--> det(sylm((%s+1)^5,(%s+3)^3))
 ans  =
  -32768.000

--> (-3 -(-1))^(5*3)     // valeur attendue
 ans  =
  -32768.

Voir aussi

• bezout — équation de Bezout pour les polynômes
• diophant — Résoud l'équation diophantienne (Bezout) p1*x1 + p2*x2 = b