xsetech

引数

wrect

大きさ 4のベクトル, 使用するサブウインドウを定義します.

frect

大きさ 4のベクトル.

logflag

大きさ 2の文字列 "xy", ただし,xおよび yは, "n"または "l"とします. "n"は通常のスケール, "l"は対数スケールを意味します. xはx軸,yはy軸を意味します.

arect

大きさ4のベクトル.

説明

xsetech は, 主にプロットに使用されるグラフィックウインドウ のサブウインドウを設定する際に使用されます. サブウインドウはパラメータwrect=[x,y,w,h] (左上の点,幅,高さ)で 指定されます. wrectの値は,カレントのグラフィックウインドウの幅または 高さの比で指定されます. 例えば,wrect=[0,0,1,1] はグラフィックウインドウ全体を使用することを 意味し, wrect=[0.5,0,0.5,1] はグラフィック領域が グラフィックウインドウの右半面となることを意味します.

xsetechは,カレントの2次元プロットのグラフィックスケールも 設定し,カレントのグラフィックスケールを指定するグラフィックルーチン (例えばplot2dのstrf="x0z"または frameflag=0)と組み合わせて使用できます.

frect=[xmin,ymin,xmax,ymax] は,グラフィックスケールを 設定する際に使用され, plot2dのrect引数によく似ています. frect が指定されない場合, グラフィックスケールのカレントの値は変更されません. rectのデフォルト値は [0,0,1,1] (ウインドウ作成時,clf('reset')によりデフォルト値に 戻された時,または記録されたグラフィックイベントをclf()で クリアした時)です.

arect=[x_left, x_right,y_up,y_down] はサブウインドウの 中にグラフィックフレームを設定する際に使用されます. グラフィックフレームは(wrectと同様に)カレントの グラフィックサブウインドウの 幅または高さに比例して指定されます. デフォルト値は 1/8*[1,1,1,1]です. arect が指定されない場合, カレントの値は変更されません.

例

// xsetechパラメータのグラフィカルな説明を得るには以下を入力してください:

exec('SCI/modules/graphics/demos/xsetechfig.sce');

// ここではグラフィックウインドウを2分割するためにxsetechが使用されます

// まず最初のサブウインドウを設定するためにxsetechを使用します

// and the graphics scale

xsetech([0,0,1.0,0.5],[-5,-3,5,3])

// グラフィックスケールを使用するためにplot2d に "001"オプションを指定してコールします

// set by xsetech

plot2d([1:10]',[1:10]',1,"001"," ")

//次に2番目のサブウインドウを設定するためにxsetechを使用します

xsetech([0,0.5,1.0,0.5])

// グラフィックスケールはデフォルトで xsetechにより[0,0,1,1]に設定され,

// plot2d のrect引数により変更します

plot2d([1:10]',[1:10]',1,"011"," ",[-6,-6,6,6])

// 4つのプロットを一つのグラフィックウインドウにプロットします

clf()

set(gca(),"font_style",2,"font_size",0);

xsetech([0,0,0.5,0.5]);

plot3d()

xsetech([0.5,0,0.5,0.5]);

plot2d()

xsetech([0.5,0.5,0.5,0.5]);

grayplot()

xsetech([0,0.5,0.5,0.5]);

histplot()

// サブウインドウのデフォルト値に戻します

xsetech([0,0,1,1])

// 変更したarectにプロット

clf('reset')

xsetech(arect=[0,0,0,0])

x=1:0.1:10;plot2d(x',sin(x)')

clf()

xsetech(arect=[1/8,1/8,1/16,1/4])

x=1:0.1:10;plot2d(x',sin(x)')

clf()

参照

• subplot — グラフィックウインドウをサブウインドウの行列に分割する
• isoview — tunes isometric rendering of graphical axes
• replot — 新しい境界を指定してカレントまたは指定した軸で再描画