Scilab Home page | Wiki | Bug tracker | Forge | Mailing list archives | ATOMS | File exchange
Please login or create an account
Change language to: English - Français - 日本語 - Русский
Ajuda do Scilab >> Biblioteca de Gráficos > 2d_plot > histplot

histplot

esboça um histograma

Seqüência de Chamamento

histplot(n, data [,normalization] [,polygon], <opt_args>)
histplot(x, data [,normalization] [,polygon], <opt_args>)
cf = histplot(..)

Parâmetros

n

inteiro positivo (número de classes)

x

vetor crescente definindo as classes (x pode ter pelo menos dois componentes)

data

vetor (dados a serem analisados)

<opt_args>

representa uma seqüência de declarações key1=value1,key2=value2 ,... onde key1, key2,... pode ser qualquer normalização ou parâmetro de plot2d opcional (style,strf,leg, rect,nax, logflag,frameflag, axesflag )No caso de normalização, o valor correspondente deve ser um escalar booleano (valor padrão %t).

cf

Computed frequencies (bins heighs)

Descrição

Esta função esboça um histograma do vetor data utilizando classes x. Quando o número n de classes é fornecido ao invés de x, as classes são escolhidas de modo igualmente espaçado e x(1) = min(data) < x(2) = x(1) + dx < ... < x(n+1) = max(data) com dx = (x(n+1)-x(1))/n .

As classes são definidas por C1 = [x(1), x(2)] e Ci = ( x(i), x(i+1)] para i >= 2. Notando Nmax o número total de data (Nmax = comprimento de data) e Ni o número de componentes de data em Ci, o valor do histograma para x em Ci é igual a Ni/(Nmax (x(i+1)-x(i))) quando normalization (normalização) for verdadeiro (caso padrão) senão, é simplesmente igual a Ni. Quando a normalização ocorre, o histograma verifica:

\int_{x(1)}^{x(n+1)}h(x)\,\mathrm{d}x=1

quando x(1)<=min(data) e max(data) <= x(n+1)

Qualquer plot2d parâmetro (opcional) pode ser fornecido; por exemplo, para esboçar um histograma com a cor número 2 (azul, se o mapa de cores padrão for utilizado) e para restringir o esboço ao retângulo [-3,3]x[0,0.5], você pode utilizar histplot(n,data, style=2, rect=[-3,0,3,0.5]).

Entre com o comando histplot() para visualizar uma demonstração.

Exemplos

Exemplo #1 : variações ao redor de um histograma de uma amostra gaussiana aleatória

d = rand(1,10000,'normal');  // a amostra gaussiana aleatória
clf(); histplot(20, d);
clf(); histplot(20, d, normalization=%f);
clf(); histplot(20, d, leg='rand(1,10000,''normal'')', style=5);
clf(); histplot(20, d, leg='rand(1,10000,''normal'')', style=16, rect=[-3,0,3,0.5]);

Exemplo #2 : histograma de uma amsostra binomial (B(6,0.5)) aleatória

d = grand(1000,1,"bin", 6, 0.5);
c = linspace(-0.5,6.5,8);

clf()
subplot(2,1,1)
histplot(c, d, style=2);
xtitle("histograma normalizado")

subplot(2,1,2)
histplot(c, d, normalization=%f, style=5);
xtitle("histograma não normalizado")

Exemplo #3 : histograma de uma amostra exponencial aleatória

lambda = 2;
X = grand(100000,1,"exp", 1/lambda);
Xmax = max(X);

clf()
histplot(40, X, style=2);
x = linspace(0,max(Xmax),100)';
plot2d(x,lambda*exp(-lambda*x),strf="000",style=5)
legend(["histograma de amostra exponencial aleatória" "curva de densidade exata"]);

Exemplo #4: the frequency polygon chart and the histogram of a gaussian random sample

n = 10;
data = rand(1,1000,"normal");

clf(); histplot(n, data, style=12, polygon=%t);
legend(["histograma normalizado" "frequency polygon chart"],"lower_caption");

Ver Também

Histórico

VersãoDescrição
5.5.0 polygon option and cf output added.
Scilab Enterprises
Copyright (c) 2011-2017 (Scilab Enterprises)
Copyright (c) 1989-2012 (INRIA)
Copyright (c) 1989-2007 (ENPC)
with contributors
Last updated:
Thu Feb 14 15:00:46 CET 2019