bode_asymp

Paramètres

sl

syslin list (SISO ou SIMO système linéaire) en temps continu ou discret (type state-space ou rational).

wmin, wmax

Réels scalaires: bornes de fréquence inférieure et supérieure (en rad/s).

Description

Trace l'asymptote du système sl.

Les arguments optionnels wmin et wmax (en rad/s) peuvent être utilisés pour tracer des asymptotes dans un périmètre précis.

A noter que les fonctions bode() ou gainplot() doivent être appelées avant bode_asymp().

Attention: cette fonction n'est pas applicable quand le premier argument est une matrice de réels.

Exemples

s = poly(0, 's');
h = syslin('c', (s^2+2*0.9*10*s+100)/(s^2+2*0.3*10.1*s+102.01));

clf(); bode(h, 0.01, 100); bode_asymp(h);

s = poly(0, 's');
h1 = syslin('c', (s^2+2*0.9*10*s+100)/(s^2+2*0.3*10.1*s+102.01));
h2 = syslin("c", (10*(s+3))/(s*(s+2)*(s^2+s+2)));

clf(); bode([h1; h2], 0.01, 100, ["h1"; "h2"]); bode_asymp([h1; h2]);

s = %s;
G = (s+10)/(s*(s+100)); // Une matrice de rational
sys = syslin("c", G); // Un système linéaire en temps continu, représentation en matrice de transfert
f_min = .0001; f_max = 1600; // Fréquences in Hz

clf(); bode(sys, f_min, f_max, "rad"); // L'argument "rad" convertit les Hz en rad/s
bode_asymp(sys, 10, 1000); // Trace les asymptotes dans le périmètre de fréquence donné (en rad/s)

s = poly(0, "s");
h = syslin("c", (s^2+2*0.9*10*s+100)/(s^2+2*0.3*10.1*s+102.01));
h = tf2ss(h);

clf();
gainplot(h, 0.01, 100, "$\frac{s^2+18 s+100}{s^2+6.06 s+102.1}$"); // Fréquences in Hertz
bode_asymp(h)

Voir Aussi

• bode — Bode plot
• black — Black-Nichols diagram of a linear dynamical system
• nyquist — nyquist plot
• gainplot — magnitude plot
• repfreq — frequency response
• g_margin — gain margin and associated crossover frequency
• p_margin — phase margin and associated crossover frequency
• calfrq — frequency response discretization
• phasemag — phase and magnitude computation
• datatips — Tool for placing and editing tips along the plotted curves
• show_margins — display gain and phase margin and associated crossover frequencies

Historique