Scilab Website | Contribute with GitLab | Mailing list archives | ATOMS toolboxes
Scilab Online Help
5.5.2 - Português

Change language to:
English - Français - 日本語 - Русский

Please note that the recommended version of Scilab is 2024.0.0. This page might be outdated.
See the recommended documentation of this function

Ajuda do Scilab >> Biblioteca de Gráficos > 2d_plot > Matplot1

Matplot1

Esboço 2d de matrizes utilizando cores

Seqüência de Chamamento

Matplot1(a,rect)

Parâmetros

a

matriz de reais de tamanho (n1,n2).

rect

[xmin,ymin,xmax,ymax]

Descrição

As entradas da matriz int(a) são utilizadas como entradas de mapa de cores no mapa de cores corrente. rect especifica um retângulo na escala corrente e a matriz é desenhada dentro deste retângulo. Cada entrada da matriz será renderizada como um pequeno retângulo preenchido com sua cor associada.

Exemplos

//--- primeiro exemplo
clf();
ax=gca();//obtendo o manipulador dos eixos correntes
ax.data_bounds=[0,0;10,10];//set the data_bounds
ax.box='on'; //desenha uma caixa
a=5*ones(11,11); a(2:10,2:10)=4; a(5:7,5:7)=2;
// primeira matriz no retângulo [1,1,3,3]
Matplot1(a,[1,1,3,3])
a=ones(10,10); a= 3*tril(a)+ 2*a; 
// segunda matriz no retângulo [5,6,7,8]
Matplot1(a,[5,6,7,8])

//--- segundo exemplo (animação)
n=100;

clf();
f = gcf();//obtendo o manipulador da figura corrente
ax = gca();//obtendo o manipulador dos eixos corrente
ax.data_bounds = [0, 0 ; 10, 10];//ajustando the data_bounds
ax.box = 'on'; //desenhando uma caixa
o = ones(n, n);
a = 3 * tril(o, -n) + 2*o;
a = a + a';
Matplot1(a, [0, 2, 7, 9])
mp = gce();
for k = (-n + 1):n,
  a = 3 * tril(o, k) + 2 * o;
  a = a + a';
  k1 = 3 * (k + 100) / 200;
  mp.data = a;
  mp.rect = [k1, 2, k1 + 7, 9];
  sleep(8); // Slow down the simulation
end

Ver Também

  • colormap — mapa de cores
  • plot2d — esboço 2d
  • Matplot — esboço 2d de uma matriz utilizando-se cores
  • grayplot — esboço 2d de uma superfície utilizando-se cores
  • Matplot_properties — Descrição das propriedades da entidade Matplot
Report an issue
<< Matplot 2d_plot Matplot_properties >>

Copyright (c) 2022-2023 (Dassault Systèmes)
Copyright (c) 2017-2022 (ESI Group)
Copyright (c) 2011-2017 (Scilab Enterprises)
Copyright (c) 1989-2012 (INRIA)
Copyright (c) 1989-2007 (ENPC)
with contributors
Last updated:
Wed Apr 01 10:24:19 CEST 2015