Scilab Website | Contribute with GitLab | Mailing list archives | ATOMS toolboxes
Scilab Online Help
5.5.0 - Português

Change language to:
English - Français - 日本語 - Русский

Please note that the recommended version of Scilab is 2024.0.0. This page might be outdated.
See the recommended documentation of this function

Ajuda do Scilab >> Biblioteca de Gráficos > axes_operations > replot

replot

reformula a área de exibição de um ou mais gráficos

Seqüência de Chamamento

replot(area)
replot(area, axesHandles)

Parâmetros

area

vetor linha de tamanho 4.

axesHandles

argumento opcional. Manipulador(es) do tipo Axes para selecionar uma ou várias entidades Axes válidas. Disponível apenas no novo modo de gráficos.

Descrição

replot é utilizado para redesenhar o conteúdo da janela de gráficos atual com novas fronteiras definidas por area = [xmin,ymin,xmax,ymax] ou rect = [xmin, ymin, zmin, xmax, ymax, zmax].

Sob o novo modo de gráficos, esta transformação pode ser aplicada a eixos específicos fornecidos por manipuladores gráficos Axes via o argumento axesHandles. Se axesHandles não for especificado, as novas fronteiras são aplicadas aos eixos correntes da figura corrente. A transformação muda os valores de data_bounds para estes eixos.

A propriedade de eixos tight_limits também deve ser ajustada para "on" para selecionar estritamente estas fronteiras (ver axes_properties).

Exemplos

// primeiro exemplo
x=[0:0.1:2*%pi]';
plot2d(x,sin(x)) 
replot([-1,-1,10,2])
// segundo exemplo
xdel(winsid());
plot() // plot demo
f=gcf();
replot([-1,-1,10,2],f.children(1)) // especificando o valor do manipulador dos eixos
replot([-3,-2,8,4],f.children(2))
// Os fronteiras indicadas pelo valor %nan não são alterados:
x = linspace(0,360,200).';
clf
plot2d(x,[sind(x) tand(x)])
ax = gca();
ax.data_bounds                // Fronteiras iniciais
replot([%nan,-10,%nan,10])    // Ymin e Ymax só são modificados
ax.data_bounds                // novas fronteiras
// 3D Fronteiras Z também pode ser modificadas :
clf
x = linspace(-4,4,100);
X = meshgrid(x);
R = (X-0.5).^2 + (X.'+0.7).^2;
Z = sinc(R);
surf(x-0.5,x+0.7,Z)
f = gcf();
f.color_map = autumncolormap(100);
ax = gca();
ax.data_bounds
sleep(3000)
replot([-5 0 -0.4 0 5 0.5])
ax.data_bounds
// Diversos gráficos podem ser cortadas simultaneamente :
clf
x = linspace(-%pi,%pi,400);
subplot(2,2,1)
plot2d(x,sin(1 ./sqrt(abs(x))))
ax1 = gca();
subplot(2,2,2)
plot2d(x,sinh(sqrt(abs(x))))
subplot(2,1,2)
plot2d(x,cos(1 ./sqrt(abs(x))))
ax2 = gca();
sleep(4000)
f = gcf();
replot([-1 %nan 1.5 %nan], [ax1 ax2])

Ver Também

  • zoom_rect — Amplia uma seleção da figura gráfica corrente
  • rubberbox — Caixa tipo liga de borracha para seleção de um retângulo
  • axes_properties — descrição das propriedades de entidades Axes (de eixos)

histórico

VersãoDescrição
5.5.0
  • Extensão para o 3D

  • Vários coordenadas gráficos podem agora ser redimensionadas simultaneamente

  • %nan pode ser usado para manter um limite como está.

Report an issue
<< plotframe axes_operations rotate_axes >>

Copyright (c) 2022-2023 (Dassault Systèmes)
Copyright (c) 2017-2022 (ESI Group)
Copyright (c) 2011-2017 (Scilab Enterprises)
Copyright (c) 1989-2012 (INRIA)
Copyright (c) 1989-2007 (ENPC)
with contributors
Last updated:
Fri Apr 11 14:18:14 CEST 2014