drawaxis

Parâmetros

dir=string

é utilizado para se especificar a direção dos tiques. string can pode ser escolhido entre 'u','r','d','l' e 'l' é o valor padrão. Os valores 'u','r','d','l' correspondem respectivamente a "para cima", "para direita", "para baixo" e "para esquerda".

tics=string

um flag definindo como os tiques são fornecidos. string pode ser escolhido entre 'v','r' e 'i', e , 'v' é o valor padrão.

x,y

dois vetores que fornecem as posições dos tiques.

val= string matrix

uma matriz de strings que, quando dada, fornece os strings a serem impressos ao longo dos eixos nas posições dos tiques.

fontsize=int

especifica o tamanho de fonte a ser utilizado para se exibir os valores ao longo dos eixos. O valor padrão é -1 que corresponde ao tamanho de fonte atual

format_n=string

formato a ser utilizado para se exibir os números ao longo dos eixos

seg= 1 ou 0

um flag que controla a exibição do segmento base do eixo (o valor padrão é 1).

sub_int=integer

um inteiro que fornece o número de subintervalos entre dois tiques maiores.

textcolor=integer

especifica a cor a ser utilizada para a exibição de valores ao longo dos eixos. O valor padrão é -1, que corresponde a cor corrente.

ticscolor=integer

especifica a cor a ser utilizada para o desenho dos tiques. O valor padrão é -1, que corresponde à cor corrente.

Descrição

drawaxis é utilizado para desenhar um eixo na direção horizontal ou vertical. A direção do eixo é dada por dir. dir = 'u' ou 'd' fornece a direção com os tiques indo para cima ('u') ou para baixo ('d'). dir = 'r' ou 'l' fornece um eixo vertical com os tiques indo para a direita ('r') ou esquerda ('l').

x e y fornecem as posições dos tiques dos eixos. Se o eixo é horizontal, então y deve ser um escalar, ou pode ser omitido, e x é um vetor Scilab. O significado de x é controlado por tics.

Se tics='v' então x fornece as posições dos tiques ao longo do eixo x.

Se tics='r' então x deve ter tamanho 3. x=[xmin,xmax,n] e n fornece o número de intervalos.

Se tics='i' então x deve ser de tamanho 4, x=[k1,k2,a,n]. Então xmin=k1*10^a, xmax=k2*10^a e n fornece o número de intervalos.

Se y for omitido, então o eixo será posicionado ao topo da moldura se dir='u' ou ao fundo se dir='d'

Por padrão, os números são impressos ao longo do eixo. Eles são impressos utilizando-se um formato padrão que pode ser alterado através de format_n. ITambém é possível exibir strings dados, e não números, isto é feito se val é fornecido. O tamanho de val deve corresponder ao número de tiques.

Exemplos

plot2d(1:10,1:10,1,"020")
// eixo horizontal
drawaxis(x=2:7,y=4,dir='u',tics='v')
// eixo horizontal na parte superior da moldura
drawaxis(x=2:7,dir='u',tics='v') 
// eixo horizontal na parte inferior da moldura
drawaxis(x=2:7,dir='d',tics='v') 

// eixo horizontal dado por um intervalo 
drawaxis(x=[2,7,3],y=4,dir='d',tics='r') 

// eixo vertical
drawaxis(x=4,y=2:7,dir='r',tics='v')
drawaxis(x=2,y=[2,7,3],dir='l',tics='r')
drawaxis(y=2:7,dir='r',tics='v')
drawaxis(y=2:7,dir='l',tics='v')

// eixo horizontal com strings exibidos nas posições dos tiques
drawaxis(x=2:7,y=8,dir='u',tics='v',val='A'+string(1:6));
// eixo vertical com strings exibidos nas posições dos tiques
drawaxis(x=8,y=2:7,dir='r',tics='v',val='B'+string(1:6));

// eixo horizontal dado com um intervalo 'i'.  
drawaxis(x=[2,5,0,3],y=9,dir='u',tics='i');
drawaxis(x=9,y=[2,5,0,3],dir='r',tics='i',sub_int=5);

// eixo horizontal de novo
drawaxis(x=2:7,y=4,dir='u',tics='v',fontsize=10,textcolor=9,ticscolor=7,seg=0,sub_int=20)

Autor

J.Ph.C.