barh

Parâmetros

h

manipulador de eixos, (padrão: h=gca() ).

y

escalar real, vetor de tamanho N ou uma matriz NxM.

x

escalar real ou um vetor de tamanho N, (padrão: se y é um vetor, então x é um vetor e o comprimento de x é igual ao comprimento de y. Se y é uma matriz, então x é um vetor e o comprimento de x é igual ao número de linhas de y)

width

(opcional), escalar real, define a largura (uma porcentagem do espaço disponível) para a barra (padrão: 0.8, i.e. 80%).

color

(opcional), um string (padrão: 'blue'), especificando a cor interior da barra barra.

style:

string, 'grouped' ou 'stacked' (padrão: 'grouped').

hdl

Esta saída opcional é um vetor contendo os identificadores de os objetos Polyline criados. Use hdl para modificar propriedades de um objeto específico ou de todos os objetos polilinha após serem criados. Para uma lista de propriedades, consulte polyline_properties.

Descrição

barh(y,...) : se y é um vetor então a função bar desenha uma poligonal que tem polyline_style tipo 6. Se y for um vetor, desenha o vetor y versus o vetor 1:size(y,'*'). Se y for uma matriz N*M, bar desenha M poligonais (tipo 6), cada poligonal corresponde a uma coluna de y versus o vetor x=1:size(y,1)

barh(x,y,...) : se y for um vetor então a função desenha uma poligonal que tem polyline_style tipo 6, onde comprimento de x = comprimento de y. Se y é uma matriz NxM então a função desenha M poligonais que possuem tipo 6. Cada poligonal corresponde a uma coluna de y versus o vetor x.

barh(h,...) : define os eixos correntes onde o desenho é realizado.

barh(...,width,...) : define a largura da(s) barra(s) em porcentagem (geralmente: 0<width<1).

barh(...,style,...) : define como as barras serão desenhadas. Se y é uma matriz NxM (então temos M poligonais de tipo 6) então há dois modos de se desenhar as M barras. A opção style= 'grouped' permite centrar as M poligonais versus cada componente de x, e a opção style = 'stacked' permite empilhá-las.

barh(...,color,...) :define a cor da barra. Funções de barra utilizam o mesmo mapa de cores que na função plot.

Se há várias chamadas a barh, a função barhomogenize permite homogeneizar a largura e estilo de todas as barras (i.e poligonais do tipo 6) inclusas nos eixos correntes.

Exemplos

// primeiro exemplo: desenhando uma barra (i.e uma poligonal com polyline_style =6),style='grouped', width=0.5, color='yellow', x=1:length(y)
scf(0);
y=[1 -3 5];
barh(y,0.5,'yellow');

// segundo exemplo: desenhando três barras (i.e três poligonais com polyline_style =6),style='grouped'
scf(1);
x=[1 2 5]; y=[1  -5 6;3 -2 7;4  -3 8];
barh(x,y);

// terceiro exemplo: style='stacked'.
scf(2);
x=[1 2 5]; y=[1 4 7;2 5 8;3 6  9];
barh(x,y,'stacked');

// quarto exemplo: width=0.2;color='green'; style='grouped'
scf(3);
x=[1 2 5]; y=[1 4 7;2 5 8;3 6 9];
barh(x,y,0.2,'green');

Ver Também

• bar — Histograma de barras
• barhomogenize — Homogeniza todas as barras inclusas nos eixos correntes
• plot — Esboço 2d
• polyline_properties — description of the Polyline entity properties

Histórico