sum

somme des éléments d'un tableau.

Séquence d'appel

y = sum(x)
y = sum(x, orientation)
y = sum(x, outtype)
y = sum(x, orientation, outtype)

Paramètres

x

Tableau de booléens (dense ou creux), entiers encodés, nombres (dense ou creux), polynômes, ou fractions rationnelles.

orientation

Cet argument peut être

un caractère : "*", "r", "c" ou "m"
un entier positif : n° de la dimension selon laquelle les sommes doivent être calculées.

outtype

une chaîne de caractères pouvant prendre les valeurs "native" ou "double".

y

un scalaire ou un tableau.

Description

Pour un tableau x, y=sum(x) renvoie dans y la somme de tous les éléments de x.

y=sum(x,orientation) retourne dans y la somme des éléments de x le long de la dimension donnée par le paramêtre orientation:

Si orientation est égal à 1 ou "r" alors:

${ y(\mathbf{1},j) = \sum_{\mathbf{i}} x(\mathbf{i},j)}$

ou

$y(\mathbf{1},j,k,\ldots) = \sum_{\mathbf{i}} x(\mathbf{i},j,k,\ldots)$
Si orientation est égal à 2 ou "c" alors:

$y(i,\mathbf{1}) = \sum_{\mathbf{j}} x(i,\mathbf{j})$

ou

$y(i,\mathbf{1},k,\ldots) = \sum_{j} x(i,\mathbf{j},k,\ldots)$
Si orientation est égal à n alors

$y(i_1,\ldots,i_{n-1},\mathbf{1},i_{n+1},\ldots) = \sum_{\mathbf{i_n}} x(i_1,\ldots,i_{n-1},\mathbf{i_n},i_{n+1},\ldots)$
y=sum(x,"*") est équivalent à y=sum(x)
y=sum(x,"m") est équivalent à y=sum(x,orientation) où orientation est l'index de la première dimension de x qui est plus grande que 1. Cette option est utilisé pour la compatibilité avec Matlab.

L'argument outtype gère la façon dont le produit est réalisé :

Pour les matrices de doubles, de polynômes, de fractions rationnelles, l'évaluation est toujours effetuée sur des nombres à virgule flottante. Les options "double" ou "native" sont équivalentes (par défaut, outtype = "double").
Pour les tableaux d'entiers,

si outtype="native", le calcul est effectué sur des nombres entiers (modulo 2^b, où b est le nombre de bits utilisés).

si outtype="double", le calcul est effectué sur des nombres à virgule flottante.

La valeur par défaut est outtype="native"
Pour les tableaux de booléens,

si outtype="native", le calcul est effectué sur des booléens (* est remplacée par &),

si outtype="double", le calcul est effectué sur des nombres à virgule flottante (%t est remplacé par 1 et %f par 0).

La valeur par défaut est outtype="double"

Remarque

Cette fonction s'applique avec les mêmes règles aux matrices creuses et aux hypermatrices.

Exemples

A=[1,2;3,4];
sum(A)
sum(A,1)

I=uint8([2 95 103;254 9 0])
sum(I) //native evaluation
sum(I,"double")
sum(I,2,"double")

s=poly(0,"s");
P=[s,%i+s;s^2,1];
sum(P),
sum(P,2)

B=[%t %t %f %f];
sum(B) //evaluation in float
sum(B,"native") //similar to or(B)

Voir aussi

plus — Addition numérique. Concaténation (collage) de textes entre eux
cumsum — sommes partielles cumulatives des éléments d'un tableau.
prod — produit des éléments d'un tableau.

Report an issue
<< sign	Opérations matricielles	Chercher et trier >>

Copyright (c) 2022-2024 (Dassault Systèmes)
Copyright (c) 2017-2022 (ESI Group)
Copyright (c) 2011-2017 (Scilab Enterprises)
Copyright (c) 1989-2012 (INRIA)
Copyright (c) 1989-2007 (ENPC)
with contributors

Last updated:
Mon Jun 17 17:52:27 CEST 2024