Scilab Website | Contribute with GitLab | Mailing list archives | ATOMS toolboxes
Scilab Online Help
2023.1.0 - Português


part

extração de strings

Seqüência de Chamamento

strings_out = part(strings_in, v)

Parâmetros

strings_in, strings_out

matriz de strings

v

vetor linha de inteiros. $ is accepted and means length(strings_in).

Descrição

Seja s[k] o caractere k do string s (ou o espaço em branco se k >length(s) ).

part retorna strings_out, uma matriz de strings, tal que strings_out(i,j) é o string "s[v(1)]...s[v(n)]" ( s=strings_in(i,j) ).

Exemplos

// retorna caracteres da posição 8 a 11
part("Como usar ""part"" ?",8:11)

// retorna caracteres da posição 2 a 4 para cada elemento
// caractere inexistente substituído por ''
c = part(['a','abc','abcd'],2:4)

// retorna o caractere da posição 1 para cada elemento e adiciona caracteres da posição 4 a 7 de cada elemento
c = part(['abcdefg','hijklmn','opqrstu'],[1,4:7]);

// retorna o caractere 4 para cada elemento, adiciona caracteres da posição 1 a 7 e adiciona o caractere da posição 4 para cada elemento
c = part(['abcdefg','hijklmn','opqrstu'],[4,1:7,4]);

// retorna o caractere da posição 1, adiciona de novo o caractere da posição 1 e o caractere da posição 2
c=part(['a','abc','abcd'],[1,1,2])

part(['a', 'abc', 'abcd'], [1])         // =>  ['a' 'a' 'a']
part(['a', 'abc', 'abcd'], [1 1])       // =>  ['aa' 'aa' 'aa']
part(['a', 'abc', 'abcd'], [1 1 2])     // =>  ['aa ' 'aab' 'aab']

// Repeating a character N times:
N = 10; part('-', ones(1:N))            // => '----------'

// Repeating a pattern N times:
N = 6; pat = '- ';
part(pat, ones(1:N).*.(1:length(pat))) // => '- - - - - - '

// Using $ = implicit length of strings:
// 1)
part(['a string' 'another longer one'], $-2:$ ) // => [ 'ing' 'one']

// 2) Another implementation for strrev():
part('Hello world', $:-1:1)        // => 'dlrow olleH'

// 3) With unranging $:
part('Hello world', [ $ 4:5 ])     // => 'dlo'

// 4) Mixing scalar or unranging $ with ranging ones is not possible:
part("Hello", [ 1 $-1:$ $ ])       // =>  error

Ver Também

Histórico

VersãoDescrição
5.5.0 $ standing for length(input_strings) is now accepted in indices of selected characters.
Report an issue
<< length Cadeias de Caracteres (Strings) prettyprint >>

Copyright (c) 2022-2023 (Dassault Systèmes)
Copyright (c) 2017-2022 (ESI Group)
Copyright (c) 2011-2017 (Scilab Enterprises)
Copyright (c) 1989-2012 (INRIA)
Copyright (c) 1989-2007 (ENPC)
with contributors
Last updated:
Mon May 22 12:42:14 CEST 2023