anti_aliasing

Description

When some curves or parts of curves have a small slope with respect to the horizontal or vertical direction of ranges of screen pixels, their raw rendering shows a stair-like aspect.

Figures have an .anti_aliasing property that can be used to smooth this rendering effect. Possible values are 'off', '2x', '4x', '8x', or '16x'.

Enabling the anti-aliasing decreases the rendering speed of graphics. In average, the time spent to build and display graphics varies approximately according to the following factors: .anti_aliasing off 2x 4x 8x 16x time spent 1 1.4 2.1 3.6 6.6

Examples

x = [0 1];
y = (0:0.025:1)';
y = [y y+0.02]';

th = 0:2:360;
xe = 4*cosd(th); xe = (0.1:0.05:1)' * xe;
ye = sind(th);   ye = (0.1:0.05:1)' * ye;

usecanvas(%t);

i = 0;
for aa = ['off' '4x' '16x']
    f = scf(i);
    f.axes_size = [300 600];
    f.figure_position(1) = 100+300*i;
    f.anti_aliasing = aa;  // <<<<<<<<
    clf
    subplot(2,1,1)
    plot2d(x,y)
    subplot(2,1,2)
    plot2d(xe',ye')
    title(".anti_aliasing = ''"+aa+"''", "fontsize",4);
    i = i+1;
end

See also

• Figure properties — グラフィックエンティティプロパティの説明
• usecanvas — Scilabグラフィックで使用されるメイン要素を取得/設定.
• lighting — 照明の概要
• pixel_drawing_mode — Figure's property setting the RGBwise pixels update mode when drawing
• system_setproperty — キーおよび値で指定したシステムプロパティを設定.