Scilab Home page | Wiki | Bug tracker | Forge | Mailing list archives | ATOMS | File exchange
Please login or create an account
Change language to: English - Français - Português - Русский

Please note that the recommended version of Scilab is 6.0.1. This page might be outdated.
See the recommended documentation of this function

Scilabヘルプ >> Graphics > property > set

set

グラフィックエンティティオブジェクトまたは またはユーザインターフェイスオブジェクトのプロパティの値を設定する.

呼び出し手順

set(prop,val)

set(h,prop)

set(h,prop,val)

set(handlePath,prop,val[,prop2, val2, ..., propn, valn])

h.prop=val

引数

h

名前のあるプロパティを設定するエンティティの グラフィックハンドル. h はハンドルのベクトルとすることができ, この場合,プロパティを修正すると,hに含まれる全てのエンティティに 適用されます.

handlePath

graphicエンティティを指すパスを有する文字列. このパスはgraphicエンティティ"Tag" プロパティおよび "figuretag/entitytag" (エンティティが図の子の場合)形式による グラフィック階層におけるその親の"Tag"プロパティ から構成されます.

"figuretag/entity1tag/entity2tag/entityntag/entitytag"のように より深い階層レベルも使用できます. 複数のパスを検索する際にワイルドカードも使用できます. パスに一致した最初のエンティティが使用されます.

prop

文字列, 設定するプロパティの名前.

val

プロパティに設定する値.

説明

このルーチンはグラフィックエンティティまたはGUIオブジェクトの 特定のプロパティの値を修正する際に使用できます. この場合,ハンドルにドット演算子を使用するのと等価です. 例えば,set(h,"background",5)h.background = 5と等価です.

プロパティの名前は文字列です. 設定する値はハンドルの型とプロパティに依存します.

存在するプロパティの全リストを取得するには, graphics_entities または (ユーザインタフェースオブジェクトについては)uicontrolを 参照ください.

set 関数はプロパティと値のみを指定するコールも可能です. この場合,プロパティは以下のどれかとします:

current_entity または hdl

set('current_entity',h) または set('hdl',h)は新規エンティティをカレントに設定します. この場合,値にはグラフィックハンドルを指定します.

current_figure

set('current_figure',fig) は新しいグラフィック図を カレントに設定します. これは scfと等価です. この場合, 値には図のハンドルを指定します.

current_axes

set('current_axes',axes) は新しい軸をカレントに 設定します. これは,scaと等価です. この場合, 値にはAxesハンドルを指定します.

set は引数にグラフィックハンドルとプロパティを指定して コールすることも可能です. ハンドルにはデフォルト図またはデフォルト軸のエンティティへのハンドルのどちらかを 指定します. プロパティの値は, "default_values"とします. この場合,デフォルトのエンティティはScilabの起動時にこの値にリセットされます. set("default_values",h)sda または sdfと等価です.

clf()

set("auto_clear","off") ;

// Plot 2Dの例

x=[-.2:0.1:2*%pi]';

plot2d(x-.3,[sin(x-1) cos(2*x)],[1 2] );

a=get("current_axes");

p1=a.children.children(1);

p2=a.children.children(2);

// 名前のあるプロパティをオブジェクト固有の値に設定

set(p2,"foreground",13);

set(p2,"polyline_style",2);

set(a,'tight_limits',"on");

set(a,"box","off");

set(a,"sub_tics",[ 7 0 ]);

set(a,"y_location","middle")

set(p2,'thickness',2);

set(p1,'mark_mode',"on");

set(p1,'mark_style',3);

plot2d(x-2,x.^2/20);

p3= a.children(1).children;

set([a p1 p2 p3],"foreground",5)

// パスを使用

f = figure("dockable", "off", "menubar", "none", "toolbar", "none", "infobar_visible", "off", "tag", "mainfig");

frameHandle = uicontrol("parent", f, "style", "frame", "position", [200 200 190 100], "tag", "myframe");

btnHandle = uicontrol("parent", frameHandle, "position", [20 20 150 30], "string", "button", "tag", "example");

set("mainfig/myframe/example", "string", "complete path");

get("mainfig/myframe/example", "string")

set("mainfig/*/example", "string", "wildcard path");

get("mainfig/*/example", "string")

set("myframe/example", "string", "partial path");

get("myframe/example", "string")

参照

  • get — グラフィックエンティティまたはユーザーインターフェイスオブジェクト からプロパティの値を取得する.
  • delete — グラフィックエンティティとその子を削除.
  • copy — グラフィックエンティティをコピー.
  • move — グラフィックエンティティおよびその子を移動, 変換する
  • graphics_entities — グラフィックスエンティティデータ構造体の説明
  • uicontrol — グラフィックユーザーインターフェイスオブジェクトを作成

履歴

バージョン記述
5.5.0
  • 最初の入力引数をグラフィックエンティティを指すパスとすることが できるようになりました.
  • 複数のプロパティ設定を一度に利用できるようになりました.
Scilab Enterprises
Copyright (c) 2011-2017 (Scilab Enterprises)
Copyright (c) 1989-2012 (INRIA)
Copyright (c) 1989-2007 (ENPC)
with contributors
Last updated:
Tue Feb 14 15:10:31 CET 2017