Scilab Home page | Wiki | Bug tracker | Forge | Mailing list archives | ATOMS | File exchange
Please login or create an account
Change language to: English - Français - Português - Русский

Please note that the recommended version of Scilab is 6.0.1. This page might be outdated.
See the recommended documentation of this function

Scilabヘルプ >> CACSD > Linear Analysis > Time Domain > rtitr

rtitr

離散時間応答 (伝達行列)

呼び出し手順

[y]=rtitr(Num,Den,u [,up,yp])

パラメータ

Num,Den

多項式行列 (それぞれの次元 : nxm および nxn)

u

実数行列 (次元 mx(t+1)

up,yp

実数行列 (up 次元 mx(maxi(degree(Den))) (デフォルト値=0) , yp 次元 nx (maxi(degree(Den))))

y

実数行列

説明

y=rtitr(Num,Den,u [,up,yp]) は, 入力 u の 伝達行列が Den^-1 Num となる 離散時間線形システムの時間応答を返します. ただし,y および u には t=0,1,...においてDen y = Num u となる関係があります.

d1=maxi(degree(Den)),および d2=maxi(degree(Num)) の場合, 多項式行列 Den(z) および Num(z) はそれぞれ以下のように 記述されます:

D(z) = D_0  + D_1  z + ... + D_d1   z^d1
N(z) = N_0  + N_1  z + ... + N_d2   z^d2

そして Den y = Num u は 次の再帰式として解釈されます:

D(0)y(t)+D(1)y(t+1)+...+ D(d1)y(t+d1)= N(0) u(t) +....+ N(d2) u(t+d2)

D(d1) は正則と仮定されます.

uの列はt=0,1,...,Tにおけるシステムの入力です:

u=[u(0) , u(1),...,u(T)]

t=0,1,...,T+d1-d2における出力が, 行列yの列になります:

y = [y(0), y(1),  .... y(T+d1-d2)]

up および yp は t < 0 における初期条件を定義します, すなわち

up = [u(-d1), ..., u(-1)  ]
yp = [y(-d1), ...  y(-1)  ]

d1 および d2の相対値に 依存して, up, yp の最も左の要素のいくつかが無視されます. up および yp のデフォルト値はゼロです: up = 0*ones(m,d1), yp=0*ones(n,d1)

z=poly(0,'z');
Num=1+z;Den=1+z;u=[1,2,3,4,5];
rtitr(Num,Den,u)-u
//Other examples
//siso
//causal
n1=1;d1=poly([1 1],'z','coeff');       // y(j)=-y(j-1)+u(j-1)
r1=[0 1 0 1 0 1 0 1 0 1 0];
r=rtitr(n1,d1,ones(1,10));norm(r1-r,1)
//hot restart
r=rtitr(n1,d1,ones(1,9),1,0);norm(r1(2:11)-r)
//non causal
n2=poly([1 1 1],'z','coeff');d2=d1;    // y(j)=-y(j-1)+u(j-1)+u(j)+u(j+1)
r2=[2 1 2 1 2 1 2 1 2];
r=rtitr(n2,d2,ones(1,10));norm(r-r2,1)
//hot restart
r=rtitr(n2,d2,ones(1,9),1,2);norm(r2(2:9)-r,1)
//
//MIMO example
//causal
d1=d1*diag([1 0.5]);n1=[1 3 1;2 4 1];r1=[5;14]*r1;
r=rtitr(n1,d1,ones(3,10));norm(r1-r,1)
//
r=rtitr(n1,d1,ones(3,9),[1;1;1],[0;0]);
norm(r1(:,2:11)-r,1)
//polynomial n1  (same ex.)
n1(1,1)=poly(1,'z','c');r=rtitr(n1,d1,ones(3,10));norm(r1-r,1)
//
r=rtitr(n1,d1,ones(3,9),[1;1;1],[0;0]);
norm(r1(:,2:11)-r,1)
//non causal
d2=d1;n2=n2*n1;r2=[5;14]*r2;
r=rtitr(n2,d2,ones(3,10));norm(r2-r)
//
r=rtitr(n2,d2,ones(3,9),[1;1;1],[10;28]);
norm(r2(:,2:9)-r,1)
//
//  State-space or transfer
a = [0.21 , 0.63 , 0.56 , 0.23 , 0.31
     0.76 , 0.85 , 0.66 , 0.23 , 0.93
     0 , 0.69 , 0.73 , 0.22 , 0.21
     0.33 , 0.88 , 0.2 , 0.88 , 0.31
     0.67 , 0.07 , 0.54 , 0.65 , 0.36];
b = [0.29 , 0.5 , 0.92
     0.57 , 0.44 , 0.04
     0.48 , 0.27 , 0.48
     0.33 , 0.63 , 0.26
     0.59 , 0.41 , 0.41];
c = [0.28 , 0.78 , 0.11 , 0.15 , 0.84
     0.13 , 0.21 , 0.69 , 0.7 , 0.41];
d = [0.41 , 0.11 , 0.56
     0.88 , 0.2 , 0.59];
s=syslin('d',a,b,c,d);
h=ss2tf(s);num=h('num');den=h('den');den=den(1,1)*eye(2,2);
u=1;u(3,10)=0;r3=flts(u,s);
r=rtitr(num,den,u);norm(r3-r,1)

参照

  • ltitr — 離散時間応答 (状態空間)
  • exp — 要素毎の指数関数
  • flts — 時間応答 (離散時間, 離散化システム)
Scilab Enterprises
Copyright (c) 2011-2017 (Scilab Enterprises)
Copyright (c) 1989-2012 (INRIA)
Copyright (c) 1989-2007 (ENPC)
with contributors
Last updated:
Tue Feb 14 15:10:29 CET 2017