Scilab Website | Contribute with GitLab | Mailing list archives | ATOMS toolboxes
Scilab Online Help
5.5.1 - Русский

Change language to:
English - Français - 日本語 - Português -

Please note that the recommended version of Scilab is 2024.0.0. This page might be outdated.
See the recommended documentation of this function

Справка Scilab >> GUI > saveGui

saveGui

Save a graphic user interface in a file

Calling Sequence

saveGui(fig, filename)

Arguments

fig

handle, the handle of the current figure

filename

character string containing the path of the file

Description

The saveGui function can be used to save a graphic user interface in a file and reloaded by the loadGui function.

saveGui(f, filename) save a current graphic handle f in file defined by filename. If the operation failed an error message in the Scilab console will be printed.

Examples

// First example
f = figure("background", -2);
h = uicontrol(f, "style", "text", ...
              "string", "This is a figure", ...
              "position", [210 180 300 100], ...
              "fontsize", 24, ...
              "backgroundcolor", [1 1 1]);

saveGui(f, fullfile(TMPDIR, "foo"))
close(f)
loadGui(fullfile(TMPDIR, "foo"));

// Second example
f = figure("default_axes", "off", ...
           "dockable", "off", ...
           "figure_name", "Sélection", ...
           "axes_size", [200 200], ...
           "infobar_visible", "off", ...
           "menubar_visible", "off", ...
           "toolbar", "none", ...
           "toolbar_visible", "off", ...
           "layout", "gridbag");
           
h1 = uicontrol(f, "style", "text", ...
                "string", "Following List :", ...
                "fontsize", 15, ...
                "constraints", createConstraints("gridbag", [1 1 2 1], [1 0], "both"));
                
h2 = uicontrol(f, "style", "popupmenu", ...
                "string", ["item1"; "item2"; "item3"], ...
                "value", 1, ...
                "fontsize", 15, ...
                "constraints", createConstraints("gridbag", [1 2 2 1], [1 0], "both"), ...
                "tag", "selection");
                
h3 = uicontrol(f, "style", "pushbutton", ...
                "string", "OK", ...
                "callback", "obj = findobj(""tag"", ""selection""); mprintf(""La valeur sélectionnée est : %s.\n"", obj.string(obj.value)); close(gcf())", ...
                "fontsize", 15, ...
                "constraints", createConstraints("gridbag", [1 3 1 1], [1 0], "both", "left"));
                
h4 = uicontrol(f, "style", "pushbutton", ...
                "string", "CANCEL", ...
                "callback", "close(gcf())", ...
                "fontsize", 15, ...
                "constraints", createConstraints("gridbag", [2 3 1 1], [1 0], "both", "right"));
                
saveGui(f, "TMPDIR/foo2.xml");
close(f)
loadGui("TMPDIR/foo2.xml")

See Also

  • loadGui — Load a graphic user interface from a saved file
  • load — Load a saved variable or a serie of variables
  • save — Save a variable or a serie of variables in a binary file

History

ВерсияОписание
5.5.0 Function saveGui introduced.
Report an issue
<< root_properties GUI setlookandfeel >>

Copyright (c) 2022-2023 (Dassault Systèmes)
Copyright (c) 2017-2022 (ESI Group)
Copyright (c) 2011-2017 (Scilab Enterprises)
Copyright (c) 1989-2012 (INRIA)
Copyright (c) 1989-2007 (ENPC)
with contributors
Last updated:
Thu Oct 02 14:01:08 CEST 2014