text_properties

説明

Textエンティティはグラフィックエンティティ階層の葉です. このエンティティは文字列描画用のパラメータを定義します.

parent:

このフィールドには親のハンドルが含まれます. textエンティティの親は"Axes" 型または "Compound"型です.

children:

このプロパティにはこのハンドルのchildren のベクトルが含まれます. しかし,現在, textハンドルにはchildrenがありません.

visible:

このフィールドはエンティティの visible プロパティを有します. この値は, "on" または "off"とします. デフォルトでテキストは可視で, このプロパティの値は "on" です. "off" の場合, テキストは画面に表示されません.

text:

オブジェクトの文字列を保持する行列.行列の各行は 水平に表示され,列は縦方向に表示されます.

Scilab 5.2以降,LaTeX または MathML 式 を指定することができます.

alignment:

文字列が列の中で整列される方法を指定します.値には, 'left','center' または 'right'を指定します.

data:

このフィールドはテキストの原点位置を表すベクトル[x,y,[z]]です．単位は,軸(axes)のデータ単位です.

box:

このフィールドの値は,"on" または "off"です. "on"の場合,テキストの周囲に縁に線が引かれ,背景を有するボックスが描画されます.

line_mode:

この論理値プロパティにより,box プロパティが "on"の時にボックスの周囲に線を描画するかどうかを指定できます. line_mode が "off"の場合,ボックスの線は 描画されません.

fill_mode:

この論理値プロパティにより,box プロパティが "on"の時にボックスの背景を塗りつぶすかどうかを指定できます. fill_mode が "off"の場合, ボックスの背景は透明ではありません..

text_box:

ユーザ座標で矩形の大きさを指定する2次元ベクトル. この矩形は,text_box_mode プロパティが 'centered' または 'filled' に設定されている時に使用されます.

text_box_mode:

以下の3種類の値をとる可能性があります : 'off', 'centered' または 'filled'. 'off'の場合, 文字列は指令したフォントで表示され, dataフィールドはテキストの左下の点の位置を指定します. 'centered'の場合, テキストは 大きさがtext_boxで指定された矩形の中心に表示されます. 'filled'の場合, 文字列のフォントの大きさは矩形を塗りつぶすように拡大されます.

'off'または'centered'モードを 使用する場合,テキストの大きさはズームの際にも一定となります. これらはグラフの注記を作成する際には最適のモードです. 逆に'filled'モードを使用した場合, テキストの大きさはグラフィックの縮尺に依存します. この場合,テキストオブジェクトをズームすることが可能です.

font_foreground:

このフィールドはテキストの文字を表示する際に使用される色を 有します.色のインデックスは(カレントのカラーマップに基づく)色インデックス である必要があります.

foreground:

このフィールドはボックスの周りに線を表示する際に使用される色を 有します.この値は(カレントのカラーマップに基づく)色インデックス である必要があります.

background:

このフィールドはボックスを塗る際に使用される色を 有します.この値は(カレントのカラーマップに基づく)色インデックス である必要があります.

font_size:

表示される文字の大きさを指定するスカラー値です. fractional_fontプロファイルが "off"の場合, 値の整数部のみが使用されます. 詳細についてはgraphics_fontsを参照ください.

font_style:

文字列の表示に使用されるフォントを指定します. これはロード済みのフォントの一つを指す正の整数です. その値は最初のフォントを指す 0 から最後のフォントを指すロード済みの フォントの数から1を引いた数までとします. 詳細についてはgraphics_fontsを参照ください.

fractional_font:

このプロパティはテキストを分数のフォントサイズにより表示するかどうかを 指定します.この値には,"on" または "off"を指定します. "on" の場合,font_sizeの浮動小数点の値が 表示の際に使用され,フォントはアンチエイリアス処理されます. "off" の場合,整数部のみが使用され,フォントは平滑化されません.

font_angle:

このプロパティはテキスト文字列の向きを定義します. 回転角(単位:度)の値を指定してください.

clip_state:

このフィールドは,テキストに関する clip_stateプロパティの値を有します. 値は以下となります :

• "off" テキストはクリップされません.

• "clipgrf" テキストはAxesボックスの外側でクリップされます.

• "on" テキストはclip_boxプロパティで指定される 矩形の外側でクリップされます.

clip_box:

このフィールドは clip_boxプロパティを有します. この値はclip_state が"off"の場合,空の行列となります. その他の場合,ベクトル[x,y,w,h] (左上の点,幅,高さ)により クリップ領域が指定されます.

user_data:

このフィールドは任意のScilab変数をtextデータ構造体に保存し, 復元する際に使用できます.

例

例

a=get("current_axes");
a.data_bounds=[0,0;1,1];
a.axes_visible = 'on' ;

xstring(0.5,0.5,"Scilab is not esilaB",0,0)

t=get("hdl")   //新規に作成されたオブジェクトのハンドルを取得

t.font_foreground=6; // フォントプロパティを変更
t.font_size=5;
t.font_style=5;

t.text=["SCILAB","is";"not","esilaB"] ; // テキストを変更
t.font_angle=90 ; // turn the strings
t.text_box = [0,0] ;
t.text_box_mode = 'centered' ; // テキストの中心を [0.5,0.5]に設定.
t.alignment = 'center' ;
t.box = 'on' ; // テキストの周囲にボックスを描画

//  Scilab 5.2以降でのみ有効
mathml="<mrow>      <mfrac>        <mrow>          <mi>d</mi>          <mi>y</mi>        </mrow>        <mrow>          <mi>d</mi>          <mi>x</mi>        </mrow>      </mfrac>      <mo>=</mo>      <mfrac>        <mn>1</mn>        <msup>          <mi>y</mi>          <mn>2</mn>        </msup>      </mfrac>    </mrow>";
t.text=["SCILAB","can write LaTeX :","$\frac{abc}{xyz}$";"or","MathML :",mathml] ;

参照

• set — グラフィックエンティティオブジェクトまたは またはユーザインターフェイスオブジェクトのプロパティの値を設定する.
• get — グラフィックエンティティまたはユーザーインターフェイスオブジェクト からプロパティの値を取得する.
• delete — グラフィックエンティティとその子を削除.
• xtitle — グラフィックスウインドにタイトルを追加する
• graphics_entities — グラフィックスエンティティデータ構造体の説明