label_properties

説明

LabelエンティティはAxesエンティティの子です. Axesエンティティが構築された時, TitleおよびLabelsのハンドルはAxesプロパティの一部として組み込まれます. このため、これらのサブオブジェクトのプロパティはAxesハンドル経由で編集可能です (gca および gda参照). Labelエンティティを直接削除することはできないことにも注意してください. このエンティティは描画するラベルに関する以下のパラメータを定義します:

parent:

このエンティティは親のハンドルを有します. labelエンティティの親は"Axes"型です.

現時点でLabelエンティティは title, x_label, y_label および z_label を構築する際に排他的に使用されていることに 注意してください.

visible:

このフィールドはエンティティのvisibleプロパティを有します. この値は"on" または "off"です. デフォルトでラベルは可視であり,このプロパティの値は"on"です. "off"の場合,ラベルは画面に表示されません.

text:

オブジェクトの文字列を有する行列.行列の行は水平に表示され,列は垂直に表示されます.

Scilab 5.2以降, LaTeX または MathML 式を書くことが可能です.

font_foreground:

このフィールドはラベルtextを表示する際に使用される色を 有します.色のインデックスは(カレントのカラーマップに基づく)色インデックス である必要があります.

foreground:

このフィールドはボックスの周りに線を表示する際に使用される色を 有します.この値は(カレントのカラーマップに基づく)色インデックス である必要があります.

background:

このフィールドはボックスを塗る際に使用される色を 有します.この値は(カレントのカラーマップに基づく)色インデックス である必要があります.

fill_mode:

このフィールドは"on"または "off"を値とします. "on" の場合, テキストの周囲に縁に線があるボックスと 背景が描画されます.

font_style:

ラベルの表示に使用されるフォントを指定します. これはロード済みのフォントの一つを指す正の整数です. その値は最初のフォントを指す 0 から最後のフォントを指すロード済みの フォントの数から1を引いた数までとします. 詳細についてはgraphics_fontsを参照ください.

font_size:

表示される文字の大きさを指定するスカラー値です. fractional_fontプロファイルが "off"の場合, 値の整数部のみが使用されます. 詳細についてはgraphics_fontsを参照ください.

fractional_font:

このプロパティはテキストを分数のフォントサイズにより表示するかどうかを 指定します.この値には,"on" または "off"を指定します. "on" の場合,font_sizeの浮動小数点の値が 表示の際に使用され,フォントはアンチエイリアス処理されます. "off" の場合,整数部のみが使用され,フォントは平滑化されません.

font_angle:

このスカラー値によりラベルを回転させることができます. フォントは度を単位として指定した角度で時計回りに回転されます. font_angleを変更すると auto_rotationプロパティが自動的に無効となる ことに注意してください.

auto_rotation:

"on"の場合, Scilab は表示の際に 最良のラベル回転角を自動的に計算します. "off"の場合, ラベルはfont_angle プロパティにより マニュアルで回転できます.

position:

この2次元ベクトルにより画面上にラベルをマニュアルで配置できます. 位置は軸のデータユニットに保存されます. font_angleを変更すると auto_positionプロパティが自動的に無効となる ことに注意してください.

auto_position:

"on"の場合, Scilab は 表示の際にグラフィックウインドウにおける最良の位置を自動的に計算します. "off"の場合,positionプロパティにより マニュアルで配置可能です.

例

a=get("current_axes");
a.title
type(a.title)
plot3d()
a.x_label
a.y_label
a.z_label
xtitle("My title","my x axis label", "Volume","Month") 

t=a.title;
t.foreground=9;
t.font_size=4;
t.font_style=5;
t.text="SCILAB";

x_label=a.x_label;
x_label.text=" Weight"
x_label.font_style= 5;
a.y_label.foreground = 12;
   
// Scilab 5.2以降, LaTeX または MathML式を書くことができます:
t.text="$\sqrt{SCILAB}$";
x_label.font_size= 5;
x_label.text="<mrow><mfrac><mrow><mn>1</mn></mrow><mrow><mn>2</mn></mrow></mfrac><mo></mo><mfenced open=""{"" close=""}""> ..
<mrow><mfrac><mrow><mfrac><mrow><mi>a</mi></mrow><mrow><mi>b</mi></mrow></mfrac></mrow><mrow><mfrac><mrow><mi>c</mi></mrow><mrow><mi>d</mi></mrow>..
</mfrac></mrow></mfrac></mrow></mfenced></mrow>"

参照

• set — グラフィックエンティティオブジェクトまたは またはユーザインターフェイスオブジェクトのプロパティの値を設定する.
• get — グラフィックエンティティまたはユーザーインターフェイスオブジェクト からプロパティの値を取得する.
• delete — グラフィックエンティティとその子を削除.
• xtitle — グラフィックスウインドにタイトルを追加する
• graphics_entities — グラフィックスエンティティデータ構造体の説明
• axes_properties — axesエンティティプロパティの説明
• text_properties — Textエンティティプロパティの説明

作者

Djalel ABDEMOUCHE