Scilab Home page | Wiki | Bug tracker | Forge | Mailing list archives | ATOMS | File exchange
Please login or create an account
Change language to: English - Français - Português -

Please note that the recommended version of Scilab is 6.0.1. This page might be outdated.
See the recommended documentation of this function

Scilab help >> Elementary Functions > Discrete mathematics > binomial

binomial

2項分布確率

呼び出し手順

pr=binomial(p,n)

パラメータ

pr

n+1 個の要素の行ベクトル

p

[0,1]の範囲の実数

n

整数 >= 1

説明

pr=binomial(p,n) は, 二項分布確率ベクトルを返します. これは, pr(k+1)n 回の成功率pの独立ベルヌーイ試行において k回成功する確率となる分布です. 言い換えると,, XをB(n,p)分布に従うランダム変数とする時の pr(k+1) = probability(X=k)で, 数値的には以下のようになります :

// first example
n=10;p=0.3; clf(); plot2d3(0:n,binomial(p,n));

// second example 
n=50;p=0.4;
mea=n*p; sigma=sqrt(n*p*(1-p));
x=( (0:n)-mea )/sigma;
clf()
plot2d(x, sigma*binomial(p,n));
deff('y=Gauss(x)','y=1/sqrt(2*%pi)*exp(-(x.^2)/2)')
plot2d(x, Gauss(x), style=2);

// by binomial formula (Caution if big n)
function pr=binomial2(p, n)
x=poly(0,'x');pr=coeff((1-p+x)^n).*horner(x^(0:n),p);
endfunction
p=1/3;n=5;
binomial(p,n)-binomial2(p,n)

// by Gamma function: gamma(n+1)=n! (Caution if big n)
p=1/3;n=5;
Cnks=gamma(n+1)./(gamma(1:n+1).*gamma(n+1:-1:1));
x=poly(0,'x');
pr=Cnks.*horner(x.^(0:n).*(1-x)^(n:-1:0),p);
pr-binomial(p,n)

参照

  • cdfbin — 累積分布関数二項分布
  • grand — 乱数生成器
Scilab Enterprises
Copyright (c) 2011-2017 (Scilab Enterprises)
Copyright (c) 1989-2012 (INRIA)
Copyright (c) 1989-2007 (ENPC)
with contributors
Last updated:
Thu Mar 03 11:00:51 CET 2011