string

Paramètres

x

Booléen, complexe, réel, entier, polynôme matrice, bibliotheque ou fonction

Description

Convertit une matrice en matrice de chaînes de caractères.

Si x est une fonction [out, in, text] = string(x) retourne 3 vecteurs de chaînes de caractères : out est le vecteur des variables de sortie, in est le vecteur des variables d'entrée, et text est le vecteur colonne du code source de la fonction.

Si x est une variable bibliotheque lib, text est un vecteur colonne de chaînes de caractères. Le premier élément contient le chemin de la bibliothèque et l'autre élément le nom des fonctions qui sont définies dans cette bibliothèque.

Les chaînes de caractères sont définies de la façon suivant, 'string' (entre quotes) ou "string" (entre double quotes); les matrices de chaînes de caractères sont définies comme des matrices constantes normales.

La concaténation des chaînes de caractères est effectuée par l'opérateur +.

pour les types Booléen, complexe, réel, entier, polynôme matrice le texte issu de string est dependant de la fonction format (voir exemples).

Exemples

string(rand(2, 2))

deff("y = mymacro(x)", "y = x + 1")
[out, in, text] = string(mymacro)
x = 123.356; 
disp("Result is " + string(x));

disp("/" + string(~%t) + "/");
disp("/" + string(%i+1) + "/");
disp("/" + string(int16(-123)) + "/");
disp("/" + string(1 + %s + %s^3) + "/");

string(corelib)

v = format();
disp(string(%pi))
format(24);
disp(string(%pi))
format(v(2))

Voir aussi

• part — extraction of strings
• length — length of object
• quote — opérateur de transposition, délimiteur de chaîne de caractères
• evstr — évaluation d'une expression
• execstr — exécution d'instructions Scilab contenues dans des chaînes de caractères
• strsubst — substitute a character string by another in a character string.
• strcat — concatenate character strings
• strindex — search position of a character string in an other string.
• sci2exp — converts an expression to a string