legends

Paramètres

strings

vecteur de chaînes de caractères, strings(i) est la légende de la ième courbe

style :

vecteur ligne entier de taille n (les styles de dessin de chaque courbe, troisième paramètre de plot2d) ou une matrice d'entiers 2 x n, style(1,k) contenant le style pour la k-ième courbe et style(2,k) contient le style de ligne (si style(1,k)>0) ou la couleur du marqueur (si style(1,k)<0).

<opt_args>

This represents a sequence of statements key1=value1,key2=value2,... where key1, key2,... can be one of the following:

opt

determine la position des légendes. Ce paramètre peut être un vecteur [x,y] spécifiant les coordonnées du point supérieur gauche de la boîte contenant les légendes. Il peut aussi prendre l'une des valeurs suivantes:

1 or "ur"

les légendes sont positionnées dans le coin supérieur droit.

2 or "ul"

les légendes sont positionnées dans le coin supérieur gauche.

3 or "ll"

les légendes sont positionnées dans le coin inférieur gauche.

4 or "lr"

les légendes sont positionnées dans le coin inférieur droit.

5 or "?"

placement intéractif avec la souris.

6 or "below"

les légendes sont positionnées en dessous du graphique (qui est alors réduit pour laisser de la place aux légendes).

with_box

booléen (%t par défaut) qui détermine la présence du cadre des légendes.

font_size

entier (1 par défaut) précisant la taille de la fonte utilisée pour les légendes.

h

Argument de sortie dans lequel est renvoyé le handle de l'objet graphique de type Legend créé par la fonction. Il peut être utilisé pour modifier ses propriétés (voir legend_properties).

Description

Dessine des légendes sur le dessin courant à partir des chaînes de caractères données.

En cas de placement interactif (opt=5) déplacer la boîte de la légende avec la souris et presser bouton de gauche pour la fixer.

Cette fonction permet de placer les légendes avec plus de liberté que l'argument leg de plot2d.

Exemples

// Exemple 1
t=0:0.1:2*%pi;
plot2d(t,[cos(t'),cos(2*t'),cos(3*t')],[-1,2 3]);
legends(['cos(t)';'cos(2*t)';'cos(3*t)'],[-1,2 3],opt="lr")

scf() ;
gca().line_style = 2;
plot2d(t,cos(t),style=5);
gca().line_style = 4;
plot2d(t,sin(t),style=3);
legends(["sin(t)";"cos(t)"],[[5;2],[3;4]], with_box=%f, opt="?")

// Exemple 2
scf() ;
subplot(221)
t=0:0.1:2*%pi;
plot2d(t,[cos(t'),cos(2*t'),cos(3*t')],[-1,2 3]);
legends(['cos(t)';'cos(2*t)';'cos(3*t)'],[-1,2 3], opt=3 )

subplot(222)
gca().line_style = 2;
plot2d(t,cos(t),style=5);
gca().line_style = 4;
plot2d(t,sin(t),style=3);
legends(["sin(t)";"cos(t)"],[[5;2],[3;4]], with_box=%f, opt=6 )

subplot(223)
gca().line_style = 2;
plot2d(t,cos(t),style=5);
gca().line_style = 4;
plot2d(t,sin(t),style=3);
legends(["sin(t)";"cos(t)"],[[5;2],[3;4]], with_box=%f, opt=1, font_size=2 )

subplot(224)
t=0:0.1:2*%pi;
plot2d(t,[cos(t'),cos(2*t'),cos(3*t')],[-1,2 3]);
legends(['cos(t)';'cos(2*t)';'cos(3*t)'],[-1,2 3], opt=2, font_size=1 )

Voir aussi

• plot2d — 2D plot
• xstring — dessine des chaînes de caractères
• xtitle — add titles on a graphics window
• legend — draw graph legend

Historique