bezout

Paramètres

p1, p2

deux polynômes réels ou deux entiers (type égal à 1, 2 ou 8)

pgcd

élément unique du type de p1 : Plus Grand Commun Diviseur de p1 et p2.

U

Matrice Unimodulaire 2x2 du type de p1, telle que [p1 p2]*U = [pgcd 0].

Description

thegcd = bezout(p1,p2) calcule le PGCD pgcd de p1 et p2

[thegcd,U] = bezout(p1,p2) calcule et retourne en outre une matrice unimodulaire (2x2) U telle que [p1,p2]*U = [pgcd,0].

Le PPCM de p1 et p2 est alors aussi donné par p1*U(1,2) (ou -p2*U(2,2)).

Si p1 ou p2 sont donnés comme des entiers décimaux (type 1), ils sont alors traités comme des polynômes de degré nul.

Exemples

// Cas des polynômes
x = poly(0,'x');
p1 = (x+1)*(x-3)^5;
p2 = (x-2)*(x-3)^3;
[pgcd,U] = bezout(p1,p2)
det(U)
clean([p1,p2]*U)
ppcm = p1*U(1,2)
lcm([p1,p2])

// Cas des entiers décimaux
i1 = 2*3^5;
i2 = 2^3*3^2;
[thegcd, U] = bezout(i1, i2)
V = [2^2*3^5 2^3*3^2 2^2*3^4*5];
[thegcd, U] = gcd(V)
V*U
lcm(V)

// Cas des entiers encodés
i1 = int32(2*3^5);
i2 = int32(2^3*3^2);
[thegcd, U] = bezout(i1, i2)
V = int32([2^2*3^5 2^3*3^2 2^2*3^4*5]);
[thegcd, U] = gcd(V)
V*U
lcm(V)

Voir aussi

• gcd — Greatest (positive) Common Divisor
• lcm — Plus petit multiple commun (PPCM) de polynômes ou d'entiers
• diophant — Résoud l'équation diophantienne (Bezout) p1*x1 + p2*x2 = b
• sylm — Matrice de Sylvester de deux polynômes
• poly — définition d'un polynôme selon racines ou coefficients, ou caractéristique d'une matrice carrée
• roots — racines d'un polynôme
• simp — simplification rationnelle
• clean — nettoie une matrice (arrondi à zéro des termes très petits)

Historique