Scilab Website | Contribute with GitLab | Mailing list archives | ATOMS toolboxes
Scilab Online Help
2023.1.0 - Português


close

Closes graphic figures, progression or wait bars, the help browser, xcos, the variables browser or editor.

Syntax

close
close(H)
close help
close xcos
close xcos!
close editvar
close browsevar

Arguments

H

Vector of graphic figures handles or ids, or of handles of progression bar or wait bar.

Description

close closes the current graphic figure (if any).

close(H) closes the figures, waitbar or progression bars whose handles or indices are in H.

close help closes the help browser.

close browsevar closes the variable browser.

close editvar closes the variable editor (it must not be docked).

close xcos closes all opened xcos windows. If some diagrams have unsaved changes, the user is asked for confirmation.

close xcos! forces closing all opened xcos windows without asking for any confirmation.

Examples

// creates  figure number 1.
h = scf();
// put a clever text in figure 1
uicontrol( h, 'style','text', ...
              'string','scilab is great', ...
              'position',[50 70 100 100], ...
              'fontsize',15);
// create figure 2
scf();
// put a text in figure 2
uicontrol( 'style','text', ...
           'string','Really great', 'position',[50 70 100 100], 'fontsize',15);

close();   // close the current graphic window (ie fig. 2)
close(h);  // close figure 1

// create a progression bar
wid1=progressionbar("Message");
// close it
close(wid1);

// Create and close several figures in a once:
scf(111); plot
scf(25); plot2d
gcf().figure_position(1) = 500;
scf(200); param3d
gcf().figure_position(1) = 700;
sleep(5000);         // Watch at them!
close([25 200 111])  // Finished!

// You are reading this example in the help browser. Now, bye:
close help

xcos
sleep(5000)
close xcos

browsevar
sleep(5000)
close browsevar

a = rand(3,5);
editvar a
sleep(5000)
close editvar

See also

  • delete — Deleta uma entidade gráfica e seus galhos
  • exit — Ends the current Scilab session
  • mclose — closes opened files
  • h5close — Close a HDF5 object

History

VersãoDescrição
6.1.1
  • Vector of several figures ids now accepted.
  • Extension to close help, close xcos, close xcos!, close browsevar, and close editvar
Report an issue
<< clipboard IGU Console properties >>

Copyright (c) 2022-2023 (Dassault Systèmes)
Copyright (c) 2017-2022 (ESI Group)
Copyright (c) 2011-2017 (Scilab Enterprises)
Copyright (c) 1989-2012 (INRIA)
Copyright (c) 1989-2007 (ENPC)
with contributors
Last updated:
Mon May 22 12:42:14 CEST 2023