Scilab Website | Contribute with GitLab | Mailing list archives | ATOMS toolboxes
Scilab Online Help
2023.0.0 - Português


GlobalProperty

Customização de aparência dos objetos (curvas, superfícies...) num comando plot ou surf.

Descrição

GlobalProperty é um argumento opcional que pode ser utilizado dentro de um comando plot() ou surf(). Permite uma customização global de todas as novas linhas esboçadas (respectivamente superfícies). Deve ser fornecido como o par{PropertyName, PropertyValue}. Vários pares podem ser ajustados ao mesmo tempo.

PropertyName deve ser um string definido a propriedade a ser ajustada. PropertyValue pode ser um real, um inteiro ou um string (um escalar, ou matriz de) dependendo do tipo de propriedade usada. Por exemplo, para especificar um (estilo de linha) traço longo vermelho (cor) com marca diamante (marca), a seqüência deve ser : 'Colo','red','LineSt','-.','Marker','diam'.

Como você pode ver, uma escrita completa dos nomes e valores das propriedades não é necessária mas os argumentos, especificados em qualquer ordem, não podem ser ambíguos. Além disso, a especificação dos strings não diferencia letras minúsculas de maiúsculas. GlobalProperty é predominante em todos os LineSpec anteriormente citados.

Aqui está uma lista completa dos PropertyName que você pode especificar (utilizando plot ou surf) e seus associados disponíveis PropertyValue. Se não forem especificadas, estas propriedades estão disponíveis para ambos objetos Polyline e Fac3d (criados respectivamente por plot e surf) e, como dito anteriormente, eles são aplicados aos novos objetos criados (linhas ou superfícies).

Algumas vezes, você pode ter dois PropertyName correspondentes a uma propriedade: o primeiro é o nome Matlab equivalente, O segundo é o nome padrão utilizado pelo Scilab(i.e.: Color ou Foreground para uma linha, ver abaixo).

"CData" or "ColorData":

uma matriz de reais especificando as cores em todos os pontos definidos pela matriz Z. TEsta propriedade esta ligada à propriedade data.color do objeto (ver surface_properties). Note que esta propriedade está disponível para superfícies apenas.

"CDataMapping" ou "ColorDataMapping":

um string com valor 'scaled' ou 'direct'. Se um data.color estiver ajustado, cada índice de cor especifica um único valor para cada vértice. cdata_mapping determina se estes índices estão em escala para serem mapeados linearmente no mapa de cores corrente (modo'scaled') ou aponta diretamente para este mapa de cores (modo 'direct'). Esta propriedade é útil quando color_flag é igual a 2,3 ou 4. Note que esta propriedade só existe em entidades Fac3d. Note também que plot3d tem modo 'direct' por padrão e surf tem modo'scaled' por padrão.

"Clipping":

um string "on" ou "off" definindo o modo de recorte ("on" por padrão). É equivalente à propriedade clip_state property. Este campo contém a propriedade (ver polyline_properties). Note que esta propriedade ainda não está disponível para entidades de superfícies.

"Color" ou "Foreground" (apenas polylines) :

Uma cor especificada pelo seu nome (texto) entre as cores nomeadas predefinidas na lista de cores), ou pelo seu código hexadecimal "#RRGGBB" (texto), ou por seu índice no mapa de cores (inteiro), ou pelo vetor [r,g,b] de suas intensidades Vermelho-Verde-Azul no intervalo [0,1].

Esta propriedade está ligada à propriedade foreground do objeto (ver polyline_properties).

"EdgeColor" or "Foreground" (apenas superfícies) :

Uma cor especificada pelo seu nome (texto) entre as cores nomeadas predefinidas na lista de cores), ou pelo seu código hexadecimal "#RRGGBB" (texto), ou por seu índice no mapa de cores (inteiro), ou pelo vetor [r,g,b] de suas intensidades Vermelho-Verde-Azul no intervalo [0,1].

Esta propriedade está ligada à propriedade foreground da superfície (ver surface_properties).

"FaceColor":

um string com valor 'none', 'flat' ou 'interp' especificando o modo como as cores das facetas são renderizadas. Quando'none' é selecionado, uma malha da superfície é desenhada; se 'flat' (modo padrão) é selecionado, os valores Fac3d color.data determinam uma cor por faceta utilizando a cor do vértice da faceta. Se o valor é 'interp', uma gradação interpolada é feita na faceta utilizando color.data para determinar a cor em cada vértice da faceta.

"LineStyle":

esta propriedade deve ser um string definindo um estilo de linha. Esta propriedade está ligada à propriedade line_style do objeto (ver polyline_properties ou surface_properties).

Especificador Estilo de linha
- linha sólida (padrão)
-- linha tracejada
: linha pontilhada
-. linha tracejada-pontilhada
none nenhuma linha
"Marker" or "MarkStyle":

um string definindo um tipo de marca. Note que se você especificar uma marca sem um estilo de linha, ambas linhas (com valor padrão sólido hablitado) e marcas são desenhadas . Esta propriedade está ligada às propriedades mark_style e mark_mode do objeto (ver polyline_properties ou surface_properties).

Especificador Tipo de marca
+ sinal de mais
o círculo
* asterísco
. ponto
x cruz
'square' or 's' quadrado
'diamond' or 'd' rombo (diamante)
^ triângulo para cima
v triângulo para baixo
> triângulo para direita
< triângulo para esquerda
'pentagram' estrela de cinco pontas (pentagrama)
'none' sem marca (padrão)
"MarkerEdgeColor" ou "MarkForeground":

Uma cor especificada pelo seu nome (texto) entre as cores nomeadas predefinidas na lista de cores), ou pelo seu código hexadecimal "#RRGGBB" (texto), ou por seu índice no mapa de cores (inteiro), ou pelo vetor [r,g,b] de suas intensidades Vermelho-Verde-Azul no intervalo [0,1].

Esta propriedade está ligada à propriedade mark_foreground do objeto (ver polyline_properties ou surface_properties).

"MarkerFaceColor" ou "MarkBackground":

Uma cor especificada pelo seu nome (texto) entre as cores nomeadas predefinidas na lista de cores), ou pelo seu código hexadecimal "#RRGGBB" (texto), ou por seu índice no mapa de cores (inteiro), ou pelo vetor [r,g,b] de suas intensidades Vermelho-Verde-Azul no intervalo [0,1].

Esta propriedade esta ligada à propriedade mark_background do objeto (ver polyline_properties ou surface_properties).

"MarkerSize" ou "MarkSize":

um escalar definindo o tamanho do marcador em unidade point. Esta propriedade está ligada a propriedade mark_size do objeto com mark_size_unit habilitado para "point" (ver polyline_properties ou surface_properties).

"Visible":

um string "on" ou "off" definindo o modo de visibilidade ("on" por padrão). Esta propriedade está ligada à propriedade visible do objeto (ver polyline_properties ou surface_properties).

"X data":

um vetor ou matriz de reais (re-)definindo os dados fornecidos para todas as linhas ou superfícies esboçadas. A respeito das dimensões, note que estes novos dados devem corresponder a todos os anteriores especificados por X isto é, todas as matrizes devem ter as mesmas dimensões. Esta propriedade está ligada à propriedade data.x do objeto (ver polyline_properties ou surface_properties).

"Y data":

um vetor ou matriz de reais (re-)definindo os dados fornecidos para todas as linhas ou superfícies esboçadas. A respeito das dimensões, note que estes novos dados devem corresponder a todos os anteriores especificados por Y data , isto é, todas as matrizes devem ter as mesmas dimensões. Esta propriedade está ligada à propriedade data.y do objeto (ver polyline_properties ou surface_properties).

"Z data":

quando usado com plot, um vetor ou matriz de reais adicionando dadosZ para todas as linhas esboçadas; com surf, uma matriz de reais (re-)definindo os dados fornecidos para todas as superfícies. A respeito das dimensões, note que estes novos dados devem corresponder a todos os anteriores especificados por X e Y data. Esta propriedade está ligada à propriedade data.z do objeto (ver polyline_properties ou surface_properties).

Exemplos

// --------------------
// com o comando plot:
// --------------------
x=1:10; // Init.
plot(x,sin(x),'colo','red','linest','-.','marker','<','markeredg','cyan','markerFace','yellow','markersize',5)
clf();

// a ordem das combinações e, {PropertyName,PropertyValue} não importa
plot(x,sin(x),'marker','p','markerfac','cyan','markersiz',10)
clf();

// a combinação de LineSpec com GlobalProperty mostra a predominância de Global Property
plot(x, x.*x, '*cya--','color', 'gr','linestyle','-', ..
     'marker','sq', 'markersize',6, 'markforegroun','red', 'markbackgro',[0.2 0.5 0.6])
clf();

//múltiplos esboços com diferentes LineSpecs e finalmente alguns GlobalProperty
clf();
t=0:%pi/20:2*%pi;
plot(t,sin(t),'ro-.',t,cos(t),'cya+',t,abs(sin(t)),'--mo','markstyl','diam')

// --------------------
// com o comando surf:
// --------------------

Z= [   0.0001    0.0013    0.0053   -0.0299   -0.1809   -0.2465   -0.1100   -0.0168   -0.0008   -0.0000
    0.0005    0.0089    0.0259   -0.3673   -1.8670   -2.4736   -1.0866   -0.1602   -0.0067    0.0000
    0.0004    0.0214    0.1739   -0.3147   -4.0919   -6.4101   -2.7589   -0.2779    0.0131    0.0020
   -0.0088   -0.0871    0.0364    1.8559    1.4995   -2.2171   -0.2729    0.8368    0.2016    0.0130
   -0.0308   -0.4313   -1.7334   -0.1148    3.0731    0.4444    2.6145    2.4410    0.4877    0.0301
   -0.0336   -0.4990   -2.3552   -2.1722    0.8856   -0.0531    2.6416    2.4064    0.4771    0.0294
   -0.0137   -0.1967   -0.8083    0.2289    3.3983    3.1955    2.4338    1.2129    0.2108    0.0125
   -0.0014   -0.0017    0.3189    2.7414    7.1622    7.1361    3.1242    0.6633    0.0674    0.0030
    0.0002    0.0104    0.1733    1.0852    2.6741    2.6725    1.1119    0.1973    0.0152    0.0005
    0.0000    0.0012    0.0183    0.1099    0.2684    0.2683    0.1107    0.0190    0.0014    0.0000];

clf();
f=gcf();
f.figure_size = [610,724];
subplot(211)
surf(Z,'facecol','interp','ydat',101:110,'edgecol','mage')
subplot(212)
surf(Z,'edgeco','b','marker','d','markersiz',9,'markerfac','k','xdata',-50:-41)

Ver Também

  • LineSpec — Customização rápida de linhas que aparecem em um esboço
  • plot — Esboço 2d
  • surf — Esboço de superfície 3d
  • clf — Clears and resets a figure or a frame uicontrol
  • polyline_properties — description of the Polyline entity properties
  • surface_properties — description of the 3D entities properties

Histórico

VersionDescription
6.0.2 The "Foreground", "markForeground", and "markBackground" colors can now be specified as named colors chosen in the full predefined colors list, or by their "#RRGGBB" hexadecimal codes, or by their indices in the colormap.
Report an issue
<< Compound properties Biblioteca de Gráficos Graphics >>

Copyright (c) 2022-2023 (Dassault Systèmes)
Copyright (c) 2017-2022 (ESI Group)
Copyright (c) 2011-2017 (Scilab Enterprises)
Copyright (c) 1989-2012 (INRIA)
Copyright (c) 1989-2007 (ENPC)
with contributors
Last updated:
Mon Mar 27 09:49:54 GMT 2023