pdiv

Parâmetros

P1, R, Q

arrays de polinômios com coeficientes reais ou complexos, do mesmo tamanho. Q são Quocientes e R são Restos.

When all remainders R are constant (degree==0), R is of type 1 (numbers) instead of 2 (polynomials).

P2

single polinomial, ou array de polinômios de size(P1).

Descrição

Divisão euclidiana elemento a elemento da array de polinômios P1 (escalar, vetor, matriz ou hipermatriz) pelo polinômio P2 ou pela array de polinômios P2. R é a array de restos, Q é a array de quocientes tal que P1 = Q*P2 + Rij ou P1 = Q.*P2 + R.

Exemplos

x = poly(0,'x');
//
p1 = (1+x^2)*(1-x);
p2 = 1-x;
[r,q] = pdiv(p1, p2)
p2*q-p1

// Com polinômios com coeficientes complexos
p1 = (x-%i)*(x+2*%i);    printf("%s\n",string(p1))
p2 = 1-x;
[r, q] = pdiv(p1, p2);   printf("%s\n", string([r;q]))
p = q*p2 + r;            printf("%s\n", string(p)); // p1 esperado

// Processamento elemento por elemento
p1 = [1+x-x^2 , x^3-x+1];
p2 = [2-x , x^2-3];
[r,q] = pdiv(p1, p2)

Ver Também

• ldiv
• pfss
• gcd