barhomogenize

Parâmetros

h

manipulador de eixos, (padrão: h=gca() ).

style

string, 'grouped' (padrão), ou 'stacked' .

width

escalar real, define a largura (uma porcentagem do espaço disponível) para a barra (padrão: 0.8).

Descrição

Se há várias chamadas a bar, a função barhomogenize permite homogeneizar a largura e estilo de todas as barras (i.e que têm polyline_style tipo 6) inclusas nos eixos correntes. Estas barras devem ter os mesmos dados x.

barhomogenize( ) : toma os valores padrões, h=gca(), width=0.8, style='grouped'.

barhomogenize(h,...) : define os eixos correntes onde o desenho é realizado.

barhomogenize(...,style,...) : define como as barras são desenhadas. A opção "grouped" permite centrar as M poligonais versus cada componente de x, e a opção "stacked" permite empilhá-las.

barhomogenize(...,width) : define a largura da(s) barra(s) em porcentagem(geralmente: 0<width<=1).

Exemplos

Primeiro exemplo: criação de uma barra amarela (i.e uma poligonal com polyline_style=6) e três barras (i.e três poligonais com polyline_style=6) do esboço).

subplot(2,3,1)
xtitle('ex1: criação de uma barra amarela e três barras')
x=1:3; y1=1:3; y2=[4 3 5;6 7 8;9 10 11];
bar(x,y1,'yellow');bar(x,y2);

// homogeneização dessas quatro barras
subplot(2,3,2)
xtitle('homogenização agrupada')
x=1:3; y1=1:3; y2=[4 3 5;6 7 8;9 10 11];
bar(x,y1,'yellow');bar(x,y2);
barhomogenize();

// homogenização empilhada dessas quatro barras
subplot(2,3,3)
xtitle('homogenização empilhada')
x=1:3; y1=1:3; y2=[4 3 5;6 7 8;9 10 11];
bar(x,y1,'yellow');bar(x,y2);
barhomogenize('stacked',1);

Segundo exemplo:criação de uma barra vermelha (i.e uma poligonal com polyline_style=6) e duas poligonais com type=1 (função de chamamento do esboço).

subplot(2,3,4)
xtitle('ex2: criação de uma barra e duas poligonais')
x=1:10; y=sin(x)/2;
bar(x,y,'red')
x1=1:10;y1=[sin(x);cos(x)]
plot(x1,y1)

// modificando o polyline_style da segunda poligonal do esboço (esta poligonal se torna em uma barra)
subplot(2,3,5)
xtitle('transformação da segunda poligonal em uma barra')
x=1:10; y=sin(x)/2;
bar(x,y,'red')
x1=1:10;y1=[sin(x);cos(x)]
plot(x1,y1)
e=gce(); e2=e.children(2); e2.polyline_style=6;
// homogenização da primeira barra (da função bar) e da segunda barra (da modificação).
subplot(2,3,6)
xtitle('homogeneização em grupo')

x=1:10; y=sin(x)/2;
bar(x,y,'red')
x1=1:10;y1=[sin(x);cos(x)]
plot(x1,y1)
e=gce(); e2=e.children(2); e2.polyline_style=6;
barhomogenize();
// mudança de estilo e largura
//barhomogenize('stacked',0.5);
//barhomogenize('stacked',1);

Ver Também

• bar
• histplot
• polyline_properties