legends

Parâmetros

strings

vetor de strings de dimensão n, strings(i) é a legenda da i-ésima curva

style

vetor linha de inteiros de dimensão n (os estilos de esboço, terceiro parâmetro de plot2d) ou uma matriz 2 x n, style(1,k) contém o estilo de esboço para a k-ésima curva e style(2,k) contém o estilo de linha (se style(1,k)>0) ou cor da marca (se style(1,k)<0).

<opt_args>

representa uma seqüência de declarações key1=value1,key2=value2,... onde key1, key2,... podem ser um dos seguintes:

opt

(opcional) especifica onde imprimir as legendas; este parâmetro pode ser um flag inteiro (ou, de modo equivalente, um string) ou um vetor [x,y] que fornece as coordenadas da quina superior esquerda da caixa de legenda. No primeiro caso, os valores possíveis são:

1 ou "ur"

as legendas são impressas no canto superior direito.

2 ou "ul"

as legendas são impressas no canto superior esquerdo.

3 ou "ll"

as legendas são impressas no canto inferior esquerdo.

4 ou "lr"

as legendas são impressas no canto inferior direito.

5 ou "?"

localização interativa com o mouse (padrão).

6 ou "below"

as legendas são impressas abaixo do gráfico (que é redimensionado de acordo).

with_box

um booleano (valor padrão %t) que ajusta se a caixa será desenhada ou não.

font_size

um inteiro (valor padrão 1) que ajusta o tamanho da fonte para os nomes na legenda.

Descrição

Põe uma legenda no esboço corrente utilizando strings especificados como rótulos.

Na localização interativa (opt=5 ou opt="?") move-se a caixa de legenda com o mouse e aperta-se o botão esquerdo para liberá-la.

Esta função permite uma localização mais flexível de legendas que o argumento de plot2d leg.

Exemplos

// Exemplo 1
t=0:0.1:2*%pi;
plot2d(t,[cos(t'),cos(2*t'),cos(3*t')],[-1,2 3]);
legends(['cos(t)';'cos(2*t)';'cos(3*t)'],[-1,2 3],opt="lr")

scf() ;
gca().line_style = 2;
plot2d(t,cos(t),style=5);
gca().line_style = 4;
plot2d(t,sin(t),style=3);
legends(["sin(t)";"cos(t)"],[[5;2],[3;4]], with_box=%f, opt="?")

// Exemplo 2
scf() ;
subplot(221)
t=0:0.1:2*%pi;
plot2d(t,[cos(t'),cos(2*t'),cos(3*t')],[-1,2 3]);
legends(['cos(t)';'cos(2*t)';'cos(3*t)'],[-1,2 3], opt=3 )

subplot(222)
gca().line_style = 2;
plot2d(t,cos(t),style=5);
gca().line_style = 4;
plot2d(t,sin(t),style=3);
legends(["sin(t)";"cos(t)"],[[5;2],[3;4]], with_box=%f, opt=6 )

subplot(223)
gca().line_style = 2;
plot2d(t,cos(t),style=5);
gca().line_style = 4;
plot2d(t,sin(t),style=3);
legends(["sin(t)";"cos(t)"],[[5;2],[3;4]], with_box=%f, opt=1, font_size=2 )

subplot(224)
t=0:0.1:2*%pi;
plot2d(t,[cos(t'),cos(2*t'),cos(3*t')],[-1,2 3]);
legends(['cos(t)';'cos(2*t)';'cos(3*t)'],[-1,2 3], opt=2, font_size=1 )

Ver Também

• plot2d
• xstring
• xtitle
• legend