Scilab Home page | Wiki | Bug tracker | Forge | Mailing list archives | ATOMS | File exchange
Please login or create an account
Change language to: English - Français - Português - 日本語 -
Справка Scilab >> Scilab > Ключевые слова Scilab > выделение

выделение

выделение элемента матрицы или списка

Синтаксис

x(i)
x(i,j)
x(i,j,k,..)
[...]=l(i)
[...]=l(k1)...(kn)(i) or [...]=l(list(k1,...,kn,i))
l(k1)...(kn)(i,j) or l(list(k1,...,kn,list(i,j))

Аргументы

x

матрица любого типа

l

переменная-список

i,j, k

индексы

k1,...kn

индексы

Описание

В СЛУЧАЕ МАТРИЦЫ

i, j, k,.. могут быть:

вещественным скаляром или вектором или матрицей с положительными элементами.
  • r=x(i,j) формирует матрицу r такую, что r(l,k)=x(int(i(l)),int(j(k))) для l от 1 до size(i,'*') и k от 1 до size(j,'*').

    Максимальное значение i (j) должно быть меньше, либо равно size(x,1) (size(x,2)).

  • r=x(i) с матрицей x размером 1x1 формирует матрицу r такую, что r(l,k)=x(int(i(l)),int(i(k))) для l от 1 до size(i,1) и k от 1 до size(i,2).

    Заметьте, что в этом случае индекс i корректен только если все её элементы равны единице.

  • r=x(i) с вектор-столбцом x формирует вектор-строку r такую, что r(l)=x(int(i(l))) для l от 1 до size(i,'*')

    Максимальное значение i должно быть меньше, либо равно size(x,'*').

  • r=x(i) с матрицей x с одним или более столбцов формирует вектор-столбец r такой, что r(l) (l от 1 до size(i,'*')) содержит int(i(l))-тые элементы вектор-столбца, сформированного конкатенацией столбцов матрицы x.

    Максимальное значение i должно быть меньше или равно size(x,'*').

символом "двоеточие" :

означает "все элементы".

  • r=x(i,:) формирует матрицу r такую, что r(l,k)=x(int(i(l)),k)) для l от 1 до size(i,'*') и k от 1 до size(x,2).

  • r=x(:,j) формирует матрицу r такую, что r(l,k)=x(l,int(j(k))) для l от 1 до size(r,1) и k от 1 до size(j,'*').

  • r=x(:) формирует вектор-столбец r, сформированный постолбцовой конкатенацией столбцов матрицы x. Это эквивалентно инструкции matrix(x,size(x,'*'),1).

вектором логических значений

Если индекс (i или j) является вектором логических значений, то он интерпретируется как find(i) или, соответственно, find(j).

полиномом

Если индекс (i или j) является вектором полиномов или подразумевается вектором полиномов, то он интерпретируется как horner(i,m) или, соответственно, horner(j,n) где m и n относятся к размерам матрицы x. Даже если эта возможность работает со всеми полиномами, рекомендуется использовать для удобочитаемости символ $.

Для матриц, у которых больше двух размерностей (см. гиперматрицы) степень размерности автоматически уменьшается, когда самые крайние правые размерности равны 1.

В СЛУЧАЕ СПИСКА (LIST) ИЛИ ТИПИЗИРОВАННОГО СПИСКА (TLIST)

В этом случае ki указывает путь до элемента подсписка структуры данных l. Разрешено рекурсивное выделение без промежуточных копий. Инструкции

[...]=l(k1)...(kn)(i)

и

[...]=l(list(k1,...,kn,i))

интерпретируются как:

lk1 = l(k1)

.. = ..

lkn = lkn-1(kn)

[...] = lkn(i).

А инструкции l(k1)...(kn)(i,j) и l(list(k1,...,kn,list(i,j)) интерпретируются как:

lk1 = l(k1)

.. = ..

lkn = lkn-1(kn)

lkn(i,j)

Когда путь указывает более одного элемента списка,то инструкция должна иметь столько аргументов слева, сколько выбрано элементов. Однако, если синтаксис выделения используется внутри вызывающей последовательности ввода функции, то каждый возвращаемый элемент списка добавляется к вызывающей последовательности функции.

Заметьте, что l(list()) -- это то же самое, что и l.

i и j могут быть:
вещественными скалярами или векторами или матрицами с положительными элементами.

[r1,...rn]=l(i) выделяет элементы i(k) из списка l и хранит их в переменных rk, где k от 1 до size(i,'*').

символом "двоеточие"

который ставится для "всех элементов".

вектором логических значений.

Если i является вектором логических значений, то он интерпретируется как find(i).

полиномом

Если i является вектором полиномов или вектором неявных полиномов, то он интерпретируется как horner(i,m), где m=size(l). Даже если эта возможность работает со всеми полиномами, рекомендуется использовать для удобочитаемости символ $.

k1 ... kn могут быть:
вещественным положительным скаляром

полиномом

интерпретируемым как horner(ki,m), где m -- соответствующий размер подсписка.

символьной строкой

связанной с именем элемента подсписка.

Примечания

Для программно определяемых типов матриц, таких как рациональные функции и линейные системы в пространстве состояний, синтаксис x(i) нельзя использовать для выделения элемента вектора из-за путаницы с выделением элемнта списка. Нужно использовать синтаксис x(1,j) или x(i,1).

Примеры

// В СЛУЧАЕ МАТРИЦЫ
a=[1 2 3;4 5 6]
a(1,2)
a([1 1],2)
a(:,1)
a(:,3:-1:1)
a(1)
a(6)
a(:)
a([%t %f %f %t])
a([%t %f],[2 3])
a(1:2,$-1)
a($:-1:1,2)
a($)
//
x='test'
x([1 1;1 1;1 1])
//
b=[1/%s,(%s+1)/(%s-1)]
b(1,1)
b(1,$)
b(2) // числитель
// в случае LIST или TLIST
l=list(1,'qwerw',%s)
l(1)
[a,b]=l([3 2])
l($)
x=tlist(l(2:3)) // формирование типизированного списка с двумя последними компонентами l
//
dts=list(1,tlist(['x';'a';'b'],10,[2 3]));
dts(2)('a')
dts(2)('b')(1,2)
[a,b]=dts(2)(['a','b'])

Смотрите также

  • find — find indices of boolean vector or matrix true elements
  • horner — polynomial/rational evaluation
  • круглые скобки — ( ) левая и правая круглые скобки
  • вставка — частичное присвоение или модификация значения переменной
Scilab Enterprises
Copyright (c) 2011-2017 (Scilab Enterprises)
Copyright (c) 1989-2012 (INRIA)
Copyright (c) 1989-2007 (ENPC)
with contributors
Last updated:
Tue Feb 14 15:13:18 CET 2017