Scilab Home page | Wiki | Bug tracker | Forge | Mailing list archives | ATOMS | File exchange
Please login or create an account
Change language to: Français - Português - 日本語 - Русский

Please note that the recommended version of Scilab is 6.1.0. This page might be outdated.
See the recommended documentation of this function

Scilab Help >> Polynomials > sfact

# sfact

discrete time spectral factorization

### Calling Sequence

`F=sfact(P)`

### Arguments

P

real polynomial matrix

### Description

Finds `F`, a spectral factor of `P`. `P` is a polynomial matrix such that each root of `P` has a mirror image w.r.t the unit circle. Problem is singular if a root is on the unit circle.

`sfact(P)` returns a polynomial matrix `F(z)` which is antistable and such that

`P = F(z)* F(1/z) *z^n`

For scalar polynomials a specific algorithm is implemented. Algorithms are adapted from Kucera's book.

### Examples

```//Simple polynomial example
z=poly(0,'z');
p=(z-1/2)*(2-z)
w=sfact(p);
w*numer(horner(w,1/z))

//matrix example
F1=[z-1/2,z+1/2,z^2+2;1,z,-z;z^3+2*z,z,1/2-z];
P=F1*gtild(F1,'d');  //P is symmetric
F=sfact(P)
roots(det(P))
roots(det(gtild(F,'d')))  //The stable roots
roots(det(F))             //The antistable roots
clean(P-F*gtild(F,'d'))

//Example of continuous time use
s=poly(0,'s');
p=-3*(s+(1+%i))*(s+(1-%i))*(s+0.5)*(s-0.5)*(s-(1+%i))*(s-(1-%i));p=real(p);
//p(s) = polynomial in s^2 , looks for stable f such that p=f(s)*f(-s)
w=horner(p,(1-s)/(1+s));  // bilinear transform w=p((1-s)/(1+s))
wn=numer(w);              //take the numerator
fn=sfact(wn);f=numer(horner(fn,(1-s)/(s+1))); //Factor and back transform
f=f/sqrt(horner(f*gtild(f,'c'),0));f=f*sqrt(horner(p,0));      //normalization
roots(f)    //f is stable
clean(f*gtild(f,'c')-p)    //f(s)*f(-s) is p(s)```

### See Also

• gtild — tilde operation
• fspecg — stable factorization of continuous time dynamical systems

### Comments

Add a comment:
Please login to comment this page.

 Report an issue << rowcompr Polynomials simp >>

 Scilab EnterprisesCopyright (c) 2011-2017 (Scilab Enterprises)Copyright (c) 1989-2012 (INRIA)Copyright (c) 1989-2007 (ENPC)with contributors Last updated:Fri Apr 11 14:06:52 CEST 2014