get

Parâmetros

h

manipulador da entidade da qual se deseja recuperar uma propriedade. h pode ser um vetor de manipuladores e, neste caso, get retorna os valores da propriedade definidos para todos os objetos identificados por h. h também pode ser 0 para se retornar as propriedades do objeto raiz.

prop

string com o nome da propriedade.

val

objeto Scilab, o valor da propriedade.

Descrição

Esta rotina pode ser utilizada para se recuperar o valor de uma propriedade especificada de uma entidade de gráficos ou objeto GUI. Neste caso, é equivalente a se usar o operador ponto ('.') em um manipulador. Por exemplo, get(h,"background") é equivalente a h.background.

Nomes de propriedades são strings. Para obter a lista de todas as propriedade existentes ver graphics_entities ou uicontrol para objetos de Interface do Usuário

get também pode ser chamado com apenas uma propriedade como argumento. Neste caso, a propriedade deve ser uma das seguintes:

current_entity or hdl

retorna o manipulador da última (e ainda existente) entidade criada. get('current_entity') e get('hdl') equivalem a gce.

current_figure

retorna o manipulador da figura (Figure) corrente. get('current_figure') equivale a gcf.

current_axes

retorna o manipulador da entidade de eixos (Axes) corrente. get('current_axes') equivale a gca.

default_figure

retorna o manipulador da figura padrão. get('default_figure') equivale a gdf.

default_axes

retorna o manipulador dos eixos padrões. get('default_axes')equivale a gda.

figures_id

retorna um vetor contendo os ids de todas as figuras gráficas abertas. get('figures_id') equivale a winsid.

Exemplos

// para entidades gráficas
clf()
    
// objetos gráficos simples
subplot(121);
x=[-.2:0.1:2*%pi]';
plot2d(x-2,x.^2);
subplot(122);
xrect(.2,.7,.5,.2);     
xrect(.3,.8,.3,.2);
xfarc(.25,.55,.1,.15,0,64*360);
xfarc(.55,.55,.1,.15,0,64*360);
xstring(0.2,.9,"Exemplo <<UM CARRO>>");
 
h=get("current_entity") //obtendo o novo objeto criado
h.font_size=3;
 
f=get("current_figure") //obtendo a figura corrente 
f.figure_size
f.figure_size=[700 500];
f.children
f.children(2).type
f.children(2).children
f.children(2).children.children.thickness=4; 
 
a=get("current_axes") //obtendo os eixos correntes
a.children.type
a.children.foreground //obtendo a cor de primeiro plano de um conjunto de objetos gráficos
a.children.foreground=9;

// para objetos de Interface do Usuário
h=uicontrol('string', 'Button'); // Abrindo uma janela com um botão.
p=get(h,'position'); // obtendo o aspecto geométrico do botão
disp('Largura do botão: ' + string(p(3))); // imprimindo a largura do botão
close(); // fechando a figura

Ver Também

• uicontrol — create a Graphic User Interface object
• root_properties — description of the root object properties.
• graphics_entities — Descrição das estruturas de dados de entidades gráficas
• set — Ajusta um valor de propriedade de uma objeto entidade gráfica ou de um objeto Interface do Usuário (User Interface)

Autor

Djalel ABDEMOUCHE