Matplot1

Parâmetros

a

matriz de reais de tamanho (n1,n2).

rect

[xmin,ymin,xmax,ymax]

hdl

O argumento de classificação na sequência é reenviado para o identificador do objeto gráfico do tipo Grayplot criado pela função. Ele pode ser usado para modificador de propriedade (veja grayplot_properties).

Descrição

As entradas da matriz int(a) são utilizadas como entradas de mapa de cores no mapa de cores corrente. rect especifica um retângulo na escala corrente e a matriz é desenhada dentro deste retângulo. Cada entrada da matriz será renderizada como um pequeno retângulo preenchido com sua cor associada.

Exemplos

//--- primeiro exemplo
clf();
ax=gca();//obtendo o manipulador dos eixos correntes
ax.data_bounds=[0,0;10,10];//set the data_bounds
ax.box='on'; //desenha uma caixa
a=5*ones(11,11); a(2:10,2:10)=4; a(5:7,5:7)=2;
// primeira matriz no retângulo [1,1,3,3]
Matplot1(a,[1,1,3,3])
a=ones(10,10); a= 3*tril(a)+ 2*a;
// segunda matriz no retângulo [5,6,7,8]
Matplot1(a,[5,6,7,8])

//--- segundo exemplo (animação)
n=100;

clf();
f = gcf();//obtendo o manipulador da figura corrente
ax = gca();//obtendo o manipulador dos eixos corrente
ax.data_bounds = [0, 0 ; 10, 10];//ajustando the data_bounds
ax.box = 'on'; //desenhando uma caixa
o = ones(n, n);
a = 3 * tril(o, -n) + 2*o;
a = a + a';
Matplot1(a, [0, 2, 7, 9])
mp = gce();
for k = (-n + 1):n,
  a = 3 * tril(o, k) + 2 * o;
  a = a + a';
  k1 = 3 * (k + 100) / 200;
  mp.data = a;
  mp.rect = [k1, 2, k1 + 7, 9];
  sleep(8); // Slow down the simulation
end

Ver Também

• colormap — set and/or get a figure colormap.
• plot2d — 2D plot
• Matplot — esboço 2d de uma matriz utilizando-se cores
• grayplot — esboço 2d de uma superfície utilizando-se cores
• Matplot_properties — Description of the Matplot entities properties

Histórico