zoom_rect

引数

rect

大きさ 4のベクトル [xmin,ymin,xmax,ymax] で, ズームする矩形を指定します.

h

Figure または Axes型のグラフィックハンドル. ズームを適用するAxesを指定します.

説明

zoom_rect 関数はAxesオブジェクトの中をズームする際に使用されます.

入力引数hはズームを適用するAxesを指定します. hが Figureハンドルの場合, ズームはその子のAxesに適用されます. h がAxesハンドルの場合,このハンドルのみにズームが適用されます. h が指定されない場合,カレントのFigureにズームが適用されます.

入力引数rect が指定された場合,ズームされるAxesの プロパティzoom_boxはこの引数により修正されます (axes_properties参照). XおよびY軸の境界はrectで置換されます. rectが指定されない場合,zoom_rectは対話的なズームとなります. ユーザはマウスで矩形を選択する必要があります. ズームされた軸の新しいzoom_box プロパティは 矩形の交点を見つけることにより計算されます.

例

clf()
x=0:0.01:6*%pi;
plot2d(x,sin(x.^2))
zoom_rect([16,-1,18,1])
//もっとズーム
zoom_rect([16,0,16.2,1])
//元に戻す
unzoom()
// axes_propertiesによりズーム
a=gca();
a.zoom_box=[16,0,16.2,1];
a.zoom_box=[];

//サブプロットを適当にズーム
clf()
x=0:0.01:6*%pi;
subplot(211)
plot2d(x,cos(x))
subplot(212)
plot2d(x,cos(2*x))
rect=[3 -2 7 10]; //カレントの軸(直近の軸)で指定された矩形座標
zoom_rect(rect)
unzoom()
//グローバルな軸をカレントの軸に設定
f=gcf();set('current_axes',f.children($))
rect=[0.4 0 0.6 1] //ウインドウの大きさの比で指定した矩形
zoom_rect(rect)
rect=[0.4 0.2 0.6 0.8]; //ウインドウの大きさの比で指定した矩形
zoom_rect(rect)

// カレントの図を対話的にズーム
zoom_rect();
// or
zoom_rect(gcf());

参照

• unzoom — グラフィックのズームを解除する
• axes_properties — axesエンティティプロパティの説明