for

Description

Si expression est un tableau (homogène ou non), variable prend les valeurs successives de chaque colonne du tableau (ou de matrix(expression, size(expression,1), -1))).

Un exemple utile : for variable = n1:pas:n2, ...,end

Si expression est une liste, for itère sur les éléments de la liste : variable prend chaque élément de la liste comme valeurs successives.

En accord avec les conventions de codage pour le langage de programmation Scilab, il est recommandé de :

• Commencer chaque instruction sur une nouvelle ligne.

• Ne pas écrire plus d'une instruction simple par ligne.

• Séparer les instructions composées sur plusieurs lignes.

Par exemple, préférer:

for i = 1:5
    disp(i);
end

à :

for i = 1:5, disp(i); end

Exemples

Itérations triviales :

for i = 1:4
    factorial(i)
end

// Par valeurs décroissantes
for j = 4:-1:1
    j
end

Itérations implicites sur les colonnes d'un tableau :

M = [1 2 ; 3 4 ; 5 6]'
for  c = M, c, end

-> M = [1 2 ; 3 4 ; 5 6]'
 M  =
   1.   3.   5.
   2.   4.   6.

--> for  c = M, c, end
 c  =
   1.
   2.

 c  =
   3.
   4.

 c  =
   5.
   6.

Colonnes d'un tableau de cells :

C = {%pi, "This is πι" ; %z^2, %t}
for  c = C, c, end

--> C = {%pi, "This is πι" ; %z^2, %t}
 C  = 
  [1x1 constant  ]  [1x1 string ]
  [1x1 polynomial]  [1x1 boolean]


--> for  c = C, c, end
 c  = 
  [1x1 constant  ]
  [1x1 polynomial]

 c  = 
  [1x1 string ]
  [1x1 boolean]

Itérations sur les éléments d'une liste :

for l = list([1 2;3 4], (1+%z)^3, 'example', [%F %T]); l, end

--> for l = list([1 2;3 4], (1+%z)^3, 'example', [%F %T]); l, end
 l  =
   1.   2.
   3.   4.

 l  =
            2   3
   1 +3z +3z  +z

 l  =
 example

 l  =
  F T

Itérations communes (imbriquées ou non) :

n = 5;
for i = 1:n
    for j = 1:n
        a(i,j) = 1/(i+j-1);
    end;
end
for j = 2:n-1
    a(j,j) = j;
end;
a

for v = a, write(%io(2),v), end
for j = 1:n, v = a(:,j), write(%io(2),v), end

Voir aussi

• while — mot-clé utilisé dans une structure while ... end
• end — Fin d'un bloc if ou select, ou d'une boucle for ou while
• do — Mot-clé utilisé pour les boucles

Historique