ВидЛинии

Описание

ВидЛинии - это необязательный аргумент, который может быть использован внутри команды построения графика plot для настройки вида каждой новой линии. Он должен быть указан в виде соединённых строк, содержащих информацию о цвете, стиле линий или маркеров. Он очень полезен для быстрого определения этих основных свойств линий.

Чтобы определить красную штрихпунктирную линию с ромбовидными маркерами, строка должна быть в виде 'r-.diam'. Как вы можете видеть, полное написание значения каждого свойства не обязательно, однако строка, которая является связкой (в любом порядке) этих трёх типов свойств, должна оставаться однозначной. Кроме того, определение строки не чувствительно к регистру.

Вот полный список типов ВидЛинии, которые вы можете определить (используя plot).

Стиль линии:

строка, определяющая стиль линии. Это свойство связано со свойством объекта line_style ("стиль линии") (см. свойства ломанной линии).

Определитель	Стиль линии
-	Сплошная линия (по умолчанию)
--	Штриховая линия
:	Пунктирная линия
-.	Штрихпунктирная линия

Цвет:

строка, определяющая цвет линии. Это свойство связано со свойством объекта foreground ("передний фон")(см. свойства ломаной линии).

Определитель	Цвет
r	Красный
g	Зелёный
b	Синий
c	Голубой
m	Пурпурный
y	Жёлтый
k	Чёрный
w	Белый

Если вы не укажете цвет (ни с помощью ВидЛинии, ни с помощью ГлобальноеСвойство), то будет использоваться таблица цветов, устанавливаемых по умолчанию. Во время рисования множества линий, команда plot автоматически перебирает в цикле эту таблицу. Вот используемые цвета:

R	G	B
0.	0.	1.
0.	0.5	0.
1.	0.	0.
0.	0.75	0.75
0.75	0.	0.75
0.75	0.75	0.
0.25	0.25	0.25

Тип маркера:

Строка, определяющая тип маркера. Заметьте, что, если вы укажете маркер без стиля линии, то будут нарисованы только маркеры. Это свойство связано со свойствами объекта mark_style ("стиль маркера") и mark_mode ("режим маркера") (см. свойства ломаной линии).

Определитель	Тип маркера
+	Знак "плюс"
o	Кружок
*	Звёздочка
.	Точка
x	Крестик
'square' или 's'	Квадрат
'diamond' или 'd'	Ромб
^	Треугольник, указывающий вверх
v	Треугольник, указывающий вниз
>	Треугольник, указывающий вправо
<	Треугольник, указывающий влево
'pentagram' или 'p'	Пятиконечная звезда (пентаграмма)
	Нет маркера (по умолчанию)

Примеры

clf();
x=1:0.1:10; // Инициализация.
plot(x,sin(x),'r-.>') // строит штрихпунктирную линию с треугольниками, указывающими вправо, центрованными на каждой точке

clf();
x=1:0.1:10;
// Если вы укажете маркер без стиля линии, то только маркеры будут нарисованы
plot(x,sin(x),'d')

clf();
x = 1:0.5:10; // Init.
// Порядок информации о цвете, стили линии или маркерах не имеет значения
// ОДНАКО информация должна быть однозначной
subplot(311);plot(x,sin(x),'.b-');
subplot(312);plot(x,sin(x),'b.-');
subplot(313);plot(x,sin(x),'b-.');// Точка принадлежит информации о стиле линии (не маркера!)

//множество графиков с различными видами линии
clf();
t=0:%pi/20:2*%pi;
plot(t,sin(t),'ro-.',t,cos(t),'cya+',t,abs(sin(t)),'--mo')

Смотрите также

• color — returns the color id of a color
• ГлобальноеСвойство — для настройки вида объектов (кривых, поверхностей, ...) в командах plot или surf
• plot — 2D plot
• clf — Clears and resets a figure or a frame uicontrol