deff

Аргументы

x, y, in1, in2, ...

входные аргументы определяемой функции. Последняя может иметь любое количество входных аргументов, от 0 до любого N.

r, r1, r2, ...

результаты на выходе определяемой функции. Последняя может иметь любое количество результатов на выходе, от 0 до любого M. Все выходные аргументы должны быть явными, то есть, записанными слева от имени функции.

funcHeadline

одиночная строка: заголовок функции, то есть, её первая строчка, указывающая локальное имя функции и списки её входных аргументов с правой стороны и выходных аргументов с левой стороны. Примеры:

• "myFunction(x,y)" : нет аргументов на выходе
• "r = myFunction(x,y)" : один аргумент на выходе
• "[a,b] = myFunction(x,y)" : два аргумента на выходе. И т.д.

Пожалуйста, обратите внимание, что a) ключевое слово function не обязательно указывать. b) запись выходных аргументов, если они есть, на левой части заголовочной строчки является обязательной.

funcBody

вектор текстов, то есть Scilab-инструкций тела функции, в том порядке, в котором они должны быть выполнены. Эти инструкции должны определять и назначать значения всех выходных аргументов. Завершающее ключевое слово "endfunction" не ожидается.

Этот вектор ожидается, когда deff(…) вызывается с двумя входными аргументами.

Одинарные или двойные кавычки внутри инструкций должны дублироваться для защиты.

definition

Отдельный текст или вектор текстов, включая как заголовочную строчку функции, так и тело.

• Если это вектор, то это эквивалентно definition = [funcHeadline ; funcBody].
• В противном случае одностроковое определение эквивалентно funcHeadline + " " + strcat(funcBody,"; ").

Пожалуйста, смотрите разделы "Описание" и "Примеры".

myFunc

Публичное имя и идентификатор определяемой функции, неявно возвращаемый в текущее окружение, либо явно присваиваемый переменной на выходе deff(…).

Когда deff(…) вызывается без явных выходных аргументов, но в качестве элемента контейнера или в качестве входного аргумента другой функции, то она неявно присваивается этому элементу или аргументу, который является анонимным. То тогда она является анонимной функцией. Например: L = list(3, deff("r=noName(x) x.^2+1"), "Hello");. Результат deff(…) присваивается L(2). Тогда L(2)(3.5) // ➜ 13.25.

Описание

deff(…) может использоваться для определения отдельной функции из инструкций Scilab, указанных через матрицу текстов, вместо любого внешнего текстового файла с инструкциями для исполнения, записанными в блок function … endfunction.

Файл исходного Scilab-кода может включать в себя определение нескольких публичных функций. Это не возможно сделать с помощью deff(…): только одну публичную функцию можно определить. Однако, как и в случае с файлом, тело определяемой функции может включать в себя один или несколько блоков function … endfunction, определяющих вложенные приватные функции.

Независимо от синтаксиса deff(…), используемого для обеспечения исходного кода (см. ниже), если он содержит синтаксическую ошибку, то deff(…) выдаст ошибку компиляции и остановит работу.

Примеры

deff('x = myplus(y,z)', 'x = y+z')
myplus(1,%i)

deff('[y, z] = mymacro(x)', ['y = 3*x+1'; 'z = a*x + x.^2'])
a = 3;
[u, v] = mymacro(2)

--> deff('x = myplus(y,z)', 'x = y+z')
--> myplus(1,%i)
 ans  =
   1. + i

--> deff('[y, z] = mymacro(x)', ['y = 3*x+1'; 'z = a*x + x.^2'])
--> a = 3;
--> [u, v] = mymacro(2)
 v  =
   10.

 u  =
   7.

clear myFunc
source = ["r = myFunc(x,y)" ; "r = x.*(x-y)"]
deff(source)
myFunc(3, -2)

--> source = ["r = myFunc(x,y)" ; "r = x.*(x-y)"]
 source  =
  "r = myFunc(x,y)"
  "r = x.*(x-y)"

--> deff(source)
--> myFunc(3, -2)
 ans  =
   15.

clear myFunc
deff "r = myFunc(x,y) r = x.*(x-y)"
myFunc(1:3, -2)

--> deff "r = myFunc(x,y) r = x.*(x-y)"
--> myFunc(1:3, -2)
 ans  =
   3.   8.   15.

clear myFunc
deff "r = myFunc(x,y) x.*(x-y)"
myFunc(1:3, -2)

--> deff "r = myFunc(x,y) x.*(x-y)"
--> myFunc(1:3, -2)
 ans  =
   3.   8.   15.

clear myFunc
deff("myFunc(x, y) messagebox(prettyprint(x.*(x-y), ""html"",""""))")
myFunc([1 2 ; 3 4], -2)

clear myFunc actualName
actualName = deff("r = myFunc(x,y) x.*(x-y)")
isdef(["myFunc" "actualName"])
actualName(1:3, -2)
myFunc(1:3, -2)

--> actualName = deff("r = myFunc(x,y) x.*(x-y)")
 actualName  =
[r]=actualName(x,y)

--> isdef(["myFunc" "actualName"])
 ans  =
  F T

--> actualName(1:3, -2)
 ans  =
   3.   8.   15.

--> myFunc(1:3, -2)
Undefined variable: myFunc

clear actualName
actualName = deff("r = @(x,y) x.*(x-y)");
actualName(1:3, -2)

--> actualName = deff("r = @(x,y) x.*(x-y)");
--> actualName(1:3, -2)
 ans  =
   3.   8.   15.

L = list("abc", deff("r = @(x,y) x.*(x-y)"), %z);
L(2)(1.1:4, -2.1)
// Мы можем извлекать и устанавливать имя анонимной функции:
Abc = L(2)
Abc(1.1:4, -2.1)

--> L = list("abc", deff("r = @(x,y) x.*(x-y)"), %z);
--> L(2)(1.1:4, -2.1)
 ans  =
   3.52   8.82   16.12

--> Abc = L(2)
 Abc  =
[r]=Abc(x,y)

--> Abc(1.1:4, -2.1)
 ans  =
   3.52   8.82   16.12

function r=test(txt, x, theFunc)
    r = x + theFunc(txt)
endfunction

test(rand(2,3), 0.7, deff("r = @(M) sum(size(M).^2)"))

--> test(rand(2,3), 0.7, deff("r = @(M) sum(size(M).^2)"))
 ans  =
   13.7

Смотрите также

• function — открывает определение функции
• exec — исполнение файла-сценария
• getd — загрузка всех функций, определённых в директории
• genlib — строит библиотеку из набора *.sci-файлов, определяющих функции в указанной директории
• jdeff — Map a static Java method onto a Scilab macro
• jcompile — Компилирует код или файл Java

История