Scilab Website | Contribute with GitLab | Mailing list archives | ATOMS toolboxes
Scilab Online Help
2023.0.0 - 日本語


csvWrite

CSVファイルを書き込む

呼び出し手順

csvWrite(M, filename)
csvWrite(M, filename, separator)
csvWrite(M, filename, separator, decimal)
csvWrite(M, filename, separator, decimal, precision)
csvWrite(M, filename, separator, decimal, precision, header)

引数

filename

1行1列の文字列行列, ファイルのパス.

M

m行n列の文字列またはdoubleの行列 (複素数がサポートされています).

separator

1行1列の文字列の行列, 列セパレータ記号.

decimal

1行1列の文字列の行列, 小数点記号. 利用可能な値は"." または ",".

precision

1行1列の文字列の行列, C形式.

header

m行1列の文字列の行列, ファイルの先頭に保存されるコメント. このオプションは,例えば, ライセンスヘッダをデータファイルに 記入するために使用できます.

説明

この関数は,行列 M を filename にカンマ区切りの値として 書き込みます.

オプションの入力引数のデフォルト値は csvDefault 関数で定義されます.

オプションの入力引数に空の行列[]を指定すると, デフォルト値が設定されます.

filename がすでに存在する場合, 上書きされます.

関係がある場合 (すなわち,'特殊'文字がある場合),ファイルはUTF-8として保存されます.

以下の例では, csvWrite および csvRead 関数を組み合わせて使用します.

// CSVファイル形式で行列を保存
M = [1:10] * 0.1;
filename = fullfile(TMPDIR, "data.csv");
csvWrite(M, filename);
// テキストとして読み込む
mgetl(filename)
r = csvRead(filename);

以下の例では, csvWrite 関数の種々のオプションを使用します.

// CSVファイル形式で行列を保存
M = rand(2,3);
filename = fullfile(TMPDIR, "data.csv");
//
// セパレータとしてタブを使用
csvWrite(M, filename,ascii(9));
mgetl(filename)
//
// 小数点として "," を使用
// (そしてセパレータとして空白を使用).
csvWrite(M, filename," ",",");
mgetl(filename)
//
// 精度を指定
// 注意: このより低い精度により読み書きサイクルで
// 誤差を発生する可能性があります!
csvWrite(M, filename,[],[],"%.8e");
mgetl(filename)
//
// コメントを指定
header = [
"// Copyright (C) INRIA"
];
csvWrite(M, filename, [], [], [], header);
mgetl(filename)

以下の例は csvWrite関数のより高度な使用例を示します.

A = [
1 0 200 %inf 0
1 1.e-300 200 %inf 0
9.99999999999990010e-001 9.99999999999999980e-201 200 3.15e300 102
9.99999999899999990e-001 1.e-100 200 296 117
1 %inf -%inf %nan 0
];
// ファイルに書き込む
filename = fullfile(TMPDIR,"foo.csv");
csvWrite(A, filename);
edit(filename)

参照

  • csvRead — CSVファイルを読み込む
  • csvTextScan — カンマ区切りの値を行列に変換
  • csvDefault — CSVファイルに関するデフォルト動作を取得/設定.

履歴

バージョン記述
5.4.0 関数が導入されました. 'csv_readwrite'モジュール に基づきます.
Report an issue
<< csvTextScan Spreadsheet read_csv >>

Copyright (c) 2022-2023 (Dassault Systèmes)
Copyright (c) 2017-2022 (ESI Group)
Copyright (c) 2011-2017 (Scilab Enterprises)
Copyright (c) 1989-2012 (INRIA)
Copyright (c) 1989-2007 (ENPC)
with contributors
Last updated:
Tue Mar 07 09:29:07 CET 2023