Scilab Website | Contribute with GitLab | Mailing list archives | ATOMS toolboxes
Scilab Online Help
2023.0.0 - Français


geomean

moyenne géométrique

Syntaxe

gm = geomean(X)
GM = geomean(X, orien)   // orien : 'r'|1|'c'|2..ndims(X)

Paramètres

X

Vecteur, matrice ou hypermatrice de réels ou de complexes.

orien

Dimension selon laquelle la moyenne géométrique est calculée. Sa valeur doit être parmi 'r', 1, 'c', 2, .. ndims(X). Les valeurs 'r' (lignes) et 1 sont équivalentes, comme 'c' (colonnes) et 2.

gm

Réel scalaire : la moyenne géométrique gm = prod(X)^(1/N), où N = length(X) est le nombre d'éléments de X.

GM

Vecteur, matrice ou hypermatrice de nombres. s = size(GM) est égal à size(X), sauf que s(orien) vaut 1 (dû à l'application projetée de geomean() selon la dimension orien).

Si X est une matrice, on a :

  • GM = geomean(X,1) => GM(1,j) = geomean(X(:,j))
  • GM = geomean(X,2) => GM(i,1) = geomean(X(i,:))

Description

geomean(X,..) calcule la moyenne géométrique des valeurs de X.

Si X ne contient que des valeurs positives ou nulles, gm ou GM sont réels. Sinon ils sont souvent complexes.

Si X est une matrice creuse (sparse), alors
  • elle est convertie en matrice pleine avant d'être traitée.
  • gm est toujours pleine.
  • GM est creuse.

Exemples

geomean(1:10) // Retourne factorial(10)^(1/10) = 4.5287286881167648

// Moyenne géométrique selon une direction choisie :
// -----------------------------------------------
m = grand(4,5, "uin", 1, 100);
m(3,2) = 0; m(2,4) = %inf; m(4,5) =  %nan
geomean(m, "r")
geomean(m, 2)
h = grand(3,5,2, "uin",1,100)
geomean(h,3)
--> m = grand(4,5, "uin", 1, 100);
--> m(3,2) = 0; m(2,4) = %inf; m(4,5) =  %nan
 m  =
   13.   5.    99.   41.   20.
   3.    92.   4.    Inf   5.
   35.   0.    36.   40.   98.
   86.   86.   66.   21.   Nan

--> geomean(m, "r")
 ans  =
   18.510058   0.   31.14479   Inf   Nan

--> geomean(m, 2)
 ans  =
   22.104082
   Inf
   0.
   Nan

--> h = grand(3,5,2, "uin",1,100)
 h  =
(:,:,1)
   10.   40.   37.   72.   30.
   10.   47.   54.   13.   19.
   44.   27.   61.   10.   27.
(:,:,2)
   96.   88.   7.    98.   35.
   54.   29.   96.   77.   8.
   94.   45.   21.   46.   3.

--> geomean(h,3)
 ans  =
   30.983867   59.329588   16.093477   84.         32.403703
   23.2379     36.91883    72.         31.638584   12.328828
   64.311741   34.85685    35.79106    21.447611   9.

// APPLICATION : Taux de croissance moyen
// --------------------------------------
// Pendant 8 ans, on mesure le diamètre D(i=1:8) du tronc d'un arbre.
D = [10 14 18 26 33 42 51 70];          // en mm

// Le taux de croissance gr(i) pour l'année #i+1 par rapport à l'année #i est, en % :
gr = (D(2:$)./D(1:$-1) - 1)*100

// Le taux de croissance moyen est donc, en % :
mgr = (geomean(1+gr/100)-1)*100

// Si ce tronc avait un taux de croissance constant, son diamètre aurait été :
D(1)*(1+mgr/100)^(0:7)
--> gr = (D(2:$)./D(1:$-1) - 1)*100
 gr  =
   40.   28.57   44.44   26.92   27.27   21.43   37.25

--> mgr = (geomean(1+gr/100)-1)*100
 mgr  =
   32.05

--> D(1)*(1+mgr/100)^(0:7)
 ans  =
   10.   13.2   17.44   23.02   30.4   40.15   53.01   70.

Voir aussi

  • prod — produit des éléments d'un tableau.
  • harmean — moyenne harmonique : inverse de la moyenne des inverses (zéros exclus)

Bibliographie

Wonacott, T.H. & Wonacott, R.J.; Introductory Statistics, fifth edition, J.Wiley & Sons, 1990.

Report an issue
<< center Moyennes - Valeur centrale harmean >>

Copyright (c) 2022-2023 (Dassault Systèmes)
Copyright (c) 2017-2022 (ESI Group)
Copyright (c) 2011-2017 (Scilab Enterprises)
Copyright (c) 1989-2012 (INRIA)
Copyright (c) 1989-2007 (ENPC)
with contributors
Last updated:
Mon Mar 27 10:12:37 GMT 2023